TAO/orbsvcs/tests/InterfaceRepo/IDL3_Test/test.idl

   1 // -*- C++ -*-
   2 #ifndef INTERFACEREPO_IDL3_TEST
   3 #define INTERFACEREPO_IDL3_TEST
   4
   5 // This module is here to contain the base valuetype for
   6 // h_key below. This base class is required when a valuetype
   7 // is used as a primary key. This module replaces the original
   8 // #include of Components.idl, and breaks the resulting
   9 // dependency of this test on CIAO. Note that this workaround
  10 // is sufficient for the IFR loader, which is the only thing
  11 // that processes this IDL file in the test. If the IDL
  12 // compiler is executed on this file, there will be
  13 // lookup errors, since it needs to find more things from
  14 // Components.idl.
  15 module Components
  16 {
  17   typeprefix Components "omg.org";
  18
  19   abstract valuetype PrimaryKeyBase {};
  20 };
  21
  22 module help
  23 {
  24   exception doh {};
  25   exception whups {};
  26 };
  27
  28 module help
  29 {
  30   interface c_supp1 {};
  31   interface c_supp2 {};
  32   component c_base supports c_supp1, c_supp2 {};
  33   valuetype v_base_base {};
  34   valuetype v_base : v_base_base {};
  35   interface v_supp1 {};
  36   abstract interface v_supp2 {};
  37
  38   valuetype h_key : Components::PrimaryKeyBase
  39   {
  40     public long id_key;
  41   };
  42
  43   interface h_supp1 {};
  44   interface h_supp2 {};
  45   home h_base supports h_supp1, h_supp2 manages c_base {};
  46 };
  47
  48 module help
  49 {
  50   interface c_provides1 {};
  51   interface c_uses1 {};
  52   interface c_uses2 {};
  53   eventtype c_emits1 {};
  54   eventtype c_publishes1 {};
  55   eventtype c_consumes1 {};
  56 };
  57
  58 module mod
  59 {
  60   component test_component : help::c_base
  61   {
  62     attribute long c_attr1
  63       getraises (help::doh)
  64       setraises (help::whups, help::doh);
  65
  66     provides help::c_provides1 test_provides1;
  67
  68     uses help::c_uses1 test_uses1;
  69
  70     uses multiple help::c_uses2 test_uses2;
  71
  72     emits help::c_emits1 test_emits1;
  73
  74     publishes help::c_publishes1 test_publishes1;
  75
  76     consumes help::c_consumes1 test_consumes1;
  77   };
  78
  79   valuetype test_valuetype
  80     : help::v_base supports help::v_supp1, help::v_supp2
  81   {
  82     attribute long c_attr1
  83       getraises (help::doh)
  84       setraises (help::whups, help::doh);
  85
  86     string v_op (inout string inoutarg,
  87                  in help::v_supp1 inarg,
  88                  out long outarg)
  89       raises (help::doh, help::whups);
  90
  91     public string test_mem1;
  92     private short test_mem2;
  93
  94     factory default_factory (in string set_tm1);
  95     factory create_tv (in string set_tm1a,
  96                        in short set_tm2)
  97       raises (help::whups, help::doh);
  98   };
  99
 100   home test_home : help::h_base
 101     manages test_component primarykey help::h_key
 102   {
 103     factory create_tc (in string set_uid)
 104       raises (help::doh);
 105
 106     finder find_tc (in long id_number,
 107                     in string id_string,
 108                     in help::h_key pkey)
 109       raises (help::whups);
 110   };
 111
 112   eventtype test_eventtype
 113     : help::v_base supports help::v_supp1, help::v_supp2
 114   {
 115     attribute long c_attr1
 116       getraises (help::doh)
 117       setraises (help::whups, help::doh);
 118
 119     string v_op (inout string inoutarg,
 120                  in help::v_supp1 inarg,
 121                  out long outarg)
 122       raises (help::doh, help::whups);
 123
 124     public string test_mem1;
 125     private short test_mem2;
 126
 127     factory default_factory (in string set_tm1);
 128     factory create_tv (in string set_tm1a,
 129                        in short set_tm2)
 130       raises (help::whups, help::doh);
 131   };
 132 };
 133
 134 #endif /* INTERFACEREPO_IDL3_TEST */
 135