lib32-libxtst/repos/multilib-x86_64/PKGBUILD

   1 # Contributor: Jan de Groot <jgc@archlinux.org>
   2
   3 _pkgbasename=libxtst
   4 pkgname=lib32-$_pkgbasename
   5 pkgver=1.2.4
   6 pkgrel=1
   7 pkgdesc="X11 Testing -- Resource extension library (32-bit)"
   8 arch=(x86_64)
   9 url="https://xorg.freedesktop.org/"
  10 license=('custom')
  11 depends=('lib32-libxext' 'lib32-libxi' 'lib32-libxfixes' $_pkgbasename)
  12 makedepends=('gcc-multilib' 'xorg-util-macros')
  13 source=(${url}/releases/individual/lib/libXtst-${pkgver}.tar.xz{,.sig})
  14 sha256sums=('84f5f30b9254b4ffee14b5b0940e2622153b0d3aed8286a3c5b7eeb340ca33c8'
  15             'SKIP')
  16 validpgpkeys=('4A193C06D35E7C670FA4EF0BA2FB9E081F2D130E') # Alan Coopersmith <alan.coopersmith@oracle.com>
  17
  18 build() {
  19   cd "${srcdir}/libXtst-${pkgver}"
  20
  21   export CC="gcc -m32"
  22   export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  23
  24   ./configure --prefix=/usr --disable-static \
  25     --libdir=/usr/lib32
  26   make
  27 }
  28
  29 package() {
  30   cd "${srcdir}/libXtst-${pkgver}"
  31
  32   make DESTDIR="${pkgdir}" install
  33
  34   rm -rf "${pkgdir}"/usr/{include,share}
  35
  36   mkdir -p "$pkgdir/usr/share/licenses"
  37   ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
  38 }