python-sortedcollections/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _pyname=sortedcollections
   4 pkgname=python-${_pyname}
   5 pkgver=2.1.0
   6 pkgrel=2
   7 pkgdesc='Sorted Collections Library'
   8 url='https://github.com/grantjenks/python-sortedcollections'
   9 arch=('any')
  10 license=('Apache')
  11 depends=('python' 'python-sortedcontainers')
  12 makedepends=('python-setuptools')
  13 checkdepends=('python-pytest' 'python-pytest-cov')
  14 source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  15 sha512sums=('7cb95af1791ab8f8c99847c1b9e0b8c1e7cc7dfe8a9df5db8bb3c96ceb2f15d7351ab4ff081d037d34dbb6c3108f4b575ca22c9e9e911a727d31b9ba3bf975f6')
  16 b2sums=('5de36155858dc055c9412ff410bd70b489aba292a2956216db95641e10dcb249b98e5c005c4d7c4fd00b25c3315c65b3f43f404737591632ac223a4045b775b5')
  17
  18 build() {
  19   cd "${pkgname}-${pkgver}"
  20   python setup.py build
  21 }
  22
  23 check() {
  24   cd "${pkgname}-${pkgver}"
  25   PYTHONPATH="$PWD/build/lib" pytest
  26 }
  27
  28 package() {
  29   cd "${pkgname}-${pkgver}"
  30   python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
  31   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  32   install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
  33 }
  34
  35 # vim: ts=2 sw=2 et: