apk-tools/repos/community-x86_64/PKGBUILD

   1 # Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
   2
   3 pkgname=apk-tools
   4 pkgver=2.12.11
   5 pkgrel=1
   6 pkgdesc="Alpine Package Keeper - package manager for alpine"
   7 url="https://gitlab.alpinelinux.org/alpine/apk-tools"
   8 arch=('x86_64')
   9 license=("GPL2")
  10 depends=(zlib openssl)
  11 makedepends=(scdoc lua53 lua53-zlib)
  12 source=("https://gitlab.alpinelinux.org/alpine/${pkgname}/-/archive/v${pkgver}/${pkgname}-v${pkgver}.tar.gz")
  13 b2sums=('f74bb618c0c8f44036adcb07fc5cc5d67a284fff00f878e1a5f28fbe262b059a5356d73f58af4fc52d635333ddd710af633bafffdc8c39924a31c87a9fc2a26d')
  14
  15 prepare() {
  16   cd "${pkgname}-v${pkgver}"
  17   sed -i -e 's:-Werror::' Make.rules
  18 }
  19
  20 build() {
  21   cd "${pkgname}-v${pkgver}"
  22   make SBINDIR=/usr/bin LIBDIR=/usr/lib
  23 }
  24
  25 check() {
  26   cd "${pkgname}-v${pkgver}"
  27   make test
  28 }
  29
  30 package() {
  31   cd "${pkgname}-v${pkgver}"
  32   make install DESTDIR="${pkgdir}" SBINDIR=/usr/bin LIBDIR=/usr/lib
  33 }
  34
  35 # vim: ts=2 sw=2 et: