python-aiostream/trunk/PKGBUILD

   1 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   2 # Contributor: Hugo Osvaldo Barrera <hugo@barrera.io>
   3
   4 _name=aiostream
   5 pkgname=python-aiostream
   6 pkgver=0.4.5
   7 pkgrel=3
   8 pkgdesc="Generator-based operators for asynchronous iteration"
   9 arch=('any')
  10 url=https://github.com/vxgmichel/aiostream
  11 license=('GPL3')
  12 depends=('python')
  13 makedepends=('git' 'python-build' 'python-installer' 'python-setuptools'
  14              'python-wheel')
  15 checkdepends=('python-pytest' 'python-pytest-asyncio')
  16 source=("git+$url.git#tag=v$pkgver")
  17 b2sums=('SKIP')
  18
  19 build() {
  20   cd $_name
  21   python -m build --wheel --skip-dependency-check --no-isolation
  22 }
  23
  24 check() {
  25   cd $_name
  26   python -m venv --system-site-packages test-env
  27   test-env/bin/python -m installer dist/*.whl
  28   test-env/bin/python -m pytest tests --strict-markers -c /dev/null
  29 }
  30
  31 package() {
  32   cd $_name
  33   python -m installer --destdir="$pkgdir" dist/*.whl
  34 }