python-puremagic/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=python-puremagic
   4 pkgver=1.15
   5 pkgrel=1
   6 pkgdesc="A Python module that will identify a file based off it's magic numbers"
   7 arch=('any')
   8 url='https://github.com/cdgriffith/puremagic'
   9 license=('MIT')
  10 depends=('python')
  11 makedepends=(
  12   'git'
  13   'python-build'
  14   'python-installer'
  15   'python-setuptools'
  16   'python-wheel'
  17 )
  18 checkdepends=('python-pytest')
  19 _commit='ff042db17e7477bbabcb9c5b7e8562a697f6b1cb'
  20 source=("$pkgname::git+$url#commit=$_commit")
  21 b2sums=('SKIP')
  22
  23 pkgver() {
  24   cd "$pkgname"
  25
  26   git describe --tags | sed 's/^v//'
  27 }
  28
  29 build() {
  30   cd "$pkgname"
  31
  32   python -m build --wheel --no-isolation
  33 }
  34
  35 check() {
  36   cd "$pkgname"
  37
  38   PYTHONPATH="$PWD:$PYTHONPATH" pytest
  39 }
  40
  41 package() {
  42   cd "$pkgname"
  43
  44   python -m installer --destdir="$pkgdir" dist/*.whl
  45
  46   # license
  47   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  48 }