lib32-libshout/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: GordonGR <gordongr@freemail.gr>
   3 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   4 # Contributor: arjan <arjan@archlinux.org>
   5 # Contributor: Jason Chu <jchu@xentac.net>
   6
   7 pkgname=lib32-libshout
   8 _pkgname=libshout
   9 pkgver=2.4.6
  10 pkgrel=3
  11 pkgdesc="Library for accessing a shoutcast/icecast server (32 bit)"
  12 arch=('x86_64')
  13 depends=('lib32-libvorbis' 'lib32-libtheora' 'lib32-speex' 'lib32-openssl' 'libshout')
  14 url="http://www.icecast.org/"
  15 options=('!emptydirs')
  16 license=('LGPL')
  17 source=("https://downloads.xiph.org/releases/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
  18 md5sums=('4a66a369a01ce790e578221fa2c8ea60')
  19 sha256sums=('39cbd4f0efdfddc9755d88217e47f8f2d7108fa767f9d58a2ba26a16d8f7c910')
  20
  21 prepare() {
  22   cd ${_pkgname}-${pkgver}
  23   sed -e 's/SSLeay_add_all_algorithms/OpenSSL_add_all_algorithms/g' -i src/tls.c
  24 }
  25
  26 build() {
  27   export CC="gcc -m32"
  28   export CXX="g++ -m32"
  29   export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  30
  31   cd ${_pkgname}-${pkgver}
  32   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libdir=/usr/lib32 --libexecdir=/usr/lib32
  33   make
  34 }
  35
  36 package() {
  37   cd ${_pkgname}-${pkgver}
  38   make DESTDIR="${pkgdir}" install
  39   rm -r "$pkgdir"/usr/{bin,include,share}
  40 }