openshadinglanguage/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 pkgname=openshadinglanguage
   3 pkgver=1.12.12.0
   4 pkgrel=1
   5 pkgdesc="Advanced shading language for production GI renderers"
   6 arch=('x86_64')
   7 url="https://github.com/imageworks/OpenShadingLanguage"
   8 license=('custom')
   9 depends=('boost-libs' 'openimageio' 'imath' 'freetype2' 'libpng'
  10          'libtiff' 'zlib' 'ncurses' 'clang')
  11 makedepends=('boost' 'cmake' 'python' 'llvm' 'ninja')
  12 optdepends=('python: the Python module')
  13 source=($pkgname-$pkgver.tar.gz::https://github.com/AcademySoftwareFoundation/OpenShadingLanguage/archive/refs/tags/v${pkgver}.tar.gz)
  14 sha512sums=('66095602cd5e500e0b9b9c2c86e80ab91f07941805163121b47f18c099ce0f77b13b69ce2b13aefaa1b4ee740541236fd939be7b16788b422591a917e7c8a2c9')
  15
  16 build() {
  17   cd OpenShadingLanguage-$pkgver
  18
  19   cmake \
  20     -B build \
  21     -GNinja \
  22     -DCMAKE_INSTALL_PREFIX=/usr \
  23     -DCMAKE_INSTALL_LIBDIR=lib \
  24     -DCMAKE_CXX_STANDARD=14 \
  25     -DLLVM_STATIC=0 \
  26     -DSTOP_ON_WARNING=OFF
  27   ninja -C build
  28 }
  29
  30 package() {
  31   cd OpenShadingLanguage-$pkgver
  32
  33   DESTDIR="$pkgdir/" ninja -C build install
  34
  35   install -Dm644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.md
  36 }
  37
  38 # vim:set ts=2 sw=2 et: