python-flask-talisman/repos/community-any/PKGBUILD

   1 # Maintainer: Jelle van der Waa <jelle@archlinux.org>
   2 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   3
   4 pkgname=python-flask-talisman
   5 _pyname=${pkgname/python-/}
   6 pkgver=1.0.0
   7 pkgrel=1
   8 pkgdesc='HTTP security headers for Flask'
   9 url='https://github.com/wntrblm/flask-talisman'
  10 arch=('any')
  11 license=('APACHE')
  12 depends=('python-flask' 'python-six')
  13 makedepends=('python-setuptools')
  14 checkdepends=('python-pytest')
  15 source=(https://github.com/wntrblm/flask-talisman/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  16 sha256sums=('015db92a07b4b4c751fb9bf3fc4f82be7fa5b07f10e3f1d8e5d5f1fc00c968bd')
  17
  18 build() {
  19   cd ${_pyname}-${pkgver}
  20   python setup.py build
  21 }
  22
  23 check() {
  24   cd ${_pyname}-${pkgver}
  25   pytest flask_talisman
  26 }
  27
  28 package() {
  29   cd ${_pyname}-${pkgver}
  30   python setup.py install --root="${pkgdir}" -O1 --skip-build
  31   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  32   install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
  33 }
  34
  35 # vim: ts=2 sw=2 et: