python-junit-xml/trunk/PKGBUILD

   1 # Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
   2
   3 pkgname=python-junit-xml
   4 # The commit that bumps version in setup.py
   5 _commit=19d3cc333d35dfd2d17d75c506336c15e5c6685a
   6 pkgver=1.9
   7 pkgrel=7
   8 pkgdesc='A Python module for creating JUnit XML test result documents'
   9 arch=(any)
  10 url='https://github.com/kyrus/python-junit-xml'
  11 license=(MIT)
  12 depends=(python python-six)
  13 makedepends=(python-setuptools git)
  14 checkdepends=(python-pytest)
  15 # There are neither tags nor PyPI source tarball...
  16 # https://github.com/kyrus/python-junit-xml/issues/68
  17 source=("git+https://github.com/kyrus/python-junit-xml?signed#commit=$_commit")
  18 sha256sums=('SKIP')
  19 validpgpkeys=(
  20   '8CCF41209F4D9FB6599E8943B797246363239E88'  # Brian Beyer <brian@redcanary.com>
  21 )
  22
  23 build() {
  24   cd python-junit-xml
  25   python setup.py build
  26 }
  27
  28 check() {
  29   cd python-junit-xml
  30   pytest -v tests
  31 }
  32
  33 package() {
  34   cd python-junit-xml
  35   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  36
  37   install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
  38 }