ruby-crass/repos/community-any/PKGBUILD

   1 # Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
   2
   3 _gemname='crass'
   4 pkgname="ruby-${_gemname}"
   5 pkgver=1.0.6
   6 pkgrel=2
   7 pkgdesc='Crass is a pure Ruby CSS parser based on the CSS Syntax Level 3 spec'
   8 arch=('any')
   9 url='https://github.com/rgrove/crass'
  10 license=('MIT')
  11 options=(!emptydirs)
  12 depends=('ruby')
  13 makedepends=('ruby-bundler' 'ruby-rake')
  14 checkdepends=('ruby-minitest')
  15 source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  16 sha512sums=('de98dea48d0cff148b3000d7388256552d1bf5a014ecbc074efc909473bc6edf2cf1db36179aaa4284eb810618dafc346757ac61708c9659045e013e6c6d4e36')
  17
  18 prepare() {
  19   cd "${_gemname}-${pkgver}"
  20
  21   # we built based on a tar archive, not a git repo
  22   sed --in-place 's/git ls-files -z/find -print0/' "${_gemname}.gemspec"
  23
  24   # update gemspec/Gemfile to allow newer version of the dependencies
  25   sed --in-place --regexp-extended 's|~>|>=|g' "${_gemname}.gemspec"
  26 }
  27
  28 build() {
  29   cd "${_gemname}-${pkgver}"
  30
  31   rake build
  32 }
  33
  34 check() {
  35   cd "${_gemname}-${pkgver}"
  36
  37   rake test
  38 }
  39
  40 package() {
  41   cd "${_gemname}-${pkgver}"
  42
  43   local _gemdir="$(gem env gemdir)"
  44
  45   gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" -n "${pkgdir}/usr/bin" "pkg/${_gemname}-${pkgver}.gem"
  46
  47   rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
  48
  49   install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  50   install -Dm 644 HISTORY.md README.md --target-directory "${pkgdir}/usr/share/doc/${pkgname}"
  51 }