virt-manager/trunk/PKGBUILD

   1 # Maintainer: Frederik Schwan <freswa at archlinux dot org>
   2 # Contributor: Christian Rebischke <chris.rebischke@archlinux.org>
   3 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   4 # Contributor: Daniel Micay <danielmicay@gmail.com>
   5 # Contributor: Jonathan Wiersma <archaur at jonw dot org>
   6
   7 pkgbase=virt-manager
   8 pkgname=(virt-install virt-manager)
   9 pkgver=4.1.0
  10 pkgrel=2
  11 arch=('any')
  12 url='https://virt-manager.org/'
  13 license=('GPL')
  14 makedepends=('python-docutils' 'python-setuptools')
  15 checkdepends=('python-pytest' 'libosinfo' 'libvirt-python' 'python-gobject' 'python-requests' 'cpio' 'cdrtools')
  16 optdepends=('x11-ssh-askpass: provide password for remote machines connected via ssh tunnel')
  17 source=("https://releases.pagure.org/virt-manager/virt-manager-${pkgver}.tar.gz")
  18 b2sums=('1b4203be81bd7b82251225d691a4d9068f268e610f049bcadb96de5b539e964ca0b001f22f06ddd8266b58b079f60046f6d11942a1e4eadbc43f0607c46bbddd')
  19
  20 build() {
  21   cd ${pkgbase}-${pkgver}
  22   python setup.py configure --default-hvs qemu,lxc
  23   python setup.py build
  24 }
  25
  26 package_virt-install() {
  27   pkgdesc='Command line tool for creating new KVM , Xen, or Linux container guests using the libvirt hypervisor'
  28   depends=('libosinfo' 'libvirt-python' 'python-gobject' 'python-requests' 'cpio' 'libisoburn')
  29
  30   cd ${pkgbase}-${pkgver}
  31   python setup.py --no-update-icon-cache --no-compile-schemas install --root "${pkgdir}"
  32   python -m compileall "${pkgdir}"/usr/share/virt-manager
  33   python -O -m compileall "${pkgdir}"/usr/share/virt-manager
  34
  35   # Split virt-manager
  36   [[ -d "${srcdir}"/virt-manager ]] && rm -r "${srcdir}"/virt-manager/
  37   mkdir -p "${srcdir}"/split/usr/{bin,share/{man/man1,virt-manager}}
  38   mv "${pkgdir}"/usr/bin/virt-manager "${srcdir}"/split/usr/bin/
  39   mv "${pkgdir}"/usr/share/{applications,glib-2.0,icons,metainfo} "${srcdir}"/split/usr/share/
  40   mv "${pkgdir}"/usr/share/man/man1/virt-manager.1 "${srcdir}"/split/usr/share/man/man1/
  41   mv "${pkgdir}"/usr/share/virt-manager/{icons,ui,virtManager} "${srcdir}"/split/usr/share/virt-manager/
  42 }
  43
  44 package_virt-manager() {
  45   pkgdesc='Desktop user interface for managing virtual machines'
  46   depends=("virt-install=${pkgver}" 'gtk-vnc' 'libvirt-glib' 'spice-gtk' 'vte3' 'python-cairo' 'gtksourceview4')
  47
  48   mv -v split/* "${pkgdir}/"
  49 }