python-fido2/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2 # Contributor: Emil Lundberg <emil@emlun.se> <emil@yubico.com>
   3
   4 pkgname=python-fido2
   5 _tag='e5d9739ed92f5586f7d53c506b834e8c9bce9868' # git rev-parse "${pkgver}"
   6 pkgver=1.1.1
   7 pkgrel=1
   8 pkgdesc='Library for FIDO 2.0, including communication with a device over USBA'
   9 url='https://github.com/Yubico/python-fido2'
  10 license=('custom:BSD-2-clause')
  11 arch=('any')
  12 depends=('python')
  13 makedepends=('git' 'python-build' 'python-installer' 'python-poetry-core')
  14 checkdepends=('python-cryptography')
  15 validpgpkeys=('20EE325B86A81BCBD3E56798F04367096FBA95E8') # Dain Nilsson <dain@yubico.com>
  16 source=("git+https://github.com/Yubico/${pkgname}.git#tag=${_tag}?signed")
  17 sha256sums=('SKIP')
  18
  19 build() {
  20   cd "${srcdir}/${pkgname}"
  21
  22   python -m build --wheel --no-isolation
  23 }
  24
  25 check() {
  26   cd "${srcdir}/${pkgname}"
  27
  28   python -m unittest discover -vs .
  29 }
  30
  31 package() {
  32   cd "${srcdir}/${pkgname}"
  33
  34   python -m installer --destdir="$pkgdir" dist/*.whl
  35
  36   install -D -m0644 'COPYING' "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  37 }