vcl/ios/iOSTransferable.cxx

   1 /* -*- Mode: C++; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4; fill-column: 100 -*- */
   2 /*
   3  * This file is part of the LibreOffice project.
   4  *
   5  * This Source Code Form is subject to the terms of the Mozilla Public
   6  * License, v. 2.0. If a copy of the MPL was not distributed with this
   7  * file, You can obtain one at http://mozilla.org/MPL/2.0/.
   8  *
   9  * This file incorporates work covered by the following license notice:
  10  *
  11  *   Licensed to the Apache Software Foundation (ASF) under one or more
  12  *   contributor license agreements. See the NOTICE file distributed
  13  *   with this work for additional information regarding copyright
  14  *   ownership. The ASF licenses this file to you under the Apache
  15  *   License, Version 2.0 (the "License"); you may not use this file
  16  *   except in compliance with the License. You may obtain a copy of
  17  *   the License at http://www.apache.org/licenses/LICENSE-2.0 .
  18  */
  19
  20 #include <sal/config.h>
  21
  22 #include <com/sun/star/datatransfer/UnsupportedFlavorException.hpp>
  23 #include <com/sun/star/lang/IllegalArgumentException.hpp>
  24 #include <sal/log.hxx>
  25 #include <sal/types.h>
  26 #include <osl/diagnose.h>
  27
  28 #include "iOSTransferable.hxx"
  29
  30 #include "DataFlavorMapping.hxx"
  31
  32 using namespace std;
  33 using namespace osl;
  34 using namespace cppu;
  35 using namespace com::sun::star::uno;
  36 using namespace com::sun::star::datatransfer;
  37 using namespace com::sun::star::lang;
  38
  39 namespace
  40 {
  41 bool isValidFlavor(const DataFlavor& aFlavor)
  42 {
  43     size_t len = aFlavor.MimeType.getLength();
  44     Type dtype = aFlavor.DataType;
  45     return ((len > 0)
  46             && ((dtype == cppu::UnoType<Sequence<sal_Int8>>::get())
  47                 || (dtype == cppu::UnoType<OUString>::get())));
  48 }
  49
  50 bool cmpAllContentTypeParameter(const Reference<XMimeContentType>& xLhs,
  51                                 const Reference<XMimeContentType>& xRhs)
  52 {
  53     Sequence<OUString> xLhsFlavors = xLhs->getParameters();
  54     Sequence<OUString> xRhsFlavors = xRhs->getParameters();
  55
  56     // Stop here if the number of parameters is different already
  57     if (xLhsFlavors.getLength() != xRhsFlavors.getLength())
  58         return false;
  59
  60     try
  61     {
  62         OUString pLhs;
  63         OUString pRhs;
  64
  65         for (sal_Int32 i = 0; i < xLhsFlavors.getLength(); i++)
  66         {
  67             pLhs = xLhs->getParameterValue(xLhsFlavors[i]);
  68             pRhs = xRhs->getParameterValue(xLhsFlavors[i]);
  69
  70             if (!pLhs.equalsIgnoreAsciiCase(pRhs))
  71             {
  72                 return false;
  73             }
  74         }
  75     }
  76     catch (IllegalArgumentException&)
  77     {
  78         return false;
  79     }
  80
  81     return true;
  82 }
  83
  84 } // unnamed namespace
  85
  86 iOSTransferable::iOSTransferable(const Reference<XMimeContentTypeFactory>& rXMimeCntFactory,
  87                                  std::shared_ptr<DataFlavorMapper> pDataFlavorMapper,
  88                                  UIPasteboard* pasteboard)
  89     : mrXMimeCntFactory(rXMimeCntFactory)
  90     , mDataFlavorMapper(pDataFlavorMapper)
  91     , mPasteboard(pasteboard)
  92 {
  93     [mPasteboard retain];
  94
  95     initClipboardItemList();
  96 }
  97
  98 iOSTransferable::~iOSTransferable() { [mPasteboard release]; }
  99
 100 Any SAL_CALL iOSTransferable::getTransferData(const DataFlavor& aFlavor)
 101 {
 102     if (!isValidFlavor(aFlavor) || !isDataFlavorSupported(aFlavor))
 103     {
 104         throw UnsupportedFlavorException("Unsupported data flavor",
 105                                          static_cast<XTransferable*>(this));
 106     }
 107
 108     bool bInternal(false);
 109     NSString* sysFormat = (aFlavor.MimeType.startsWith("image/png"))
 110                               ? DataFlavorMapper::openOfficeImageToSystemFlavor(mPasteboard)
 111                               : mDataFlavorMapper->openOfficeToSystemFlavor(aFlavor, bInternal);
 112     DataProviderPtr_t dp;
 113
 114     NSData* sysData = [mPasteboard dataForPasteboardType:sysFormat];
 115     dp = DataFlavorMapper::getDataProvider(sysFormat, sysData);
 116
 117     if (dp.get() == nullptr)
 118     {
 119         throw UnsupportedFlavorException("Unsupported data flavor",
 120                                          static_cast<XTransferable*>(this));
 121     }
 122
 123     return dp->getOOoData();
 124 }
 125
 126 Sequence<DataFlavor> SAL_CALL iOSTransferable::getTransferDataFlavors() { return mFlavorList; }
 127
 128 sal_Bool SAL_CALL iOSTransferable::isDataFlavorSupported(const DataFlavor& aFlavor)
 129 {
 130     for (sal_Int32 i = 0; i < mFlavorList.getLength(); i++)
 131         if (compareDataFlavors(aFlavor, mFlavorList[i]))
 132             return true;
 133
 134     return false;
 135 }
 136
 137 void iOSTransferable::initClipboardItemList()
 138 {
 139     NSArray* pboardFormats = [mPasteboard pasteboardTypes];
 140
 141     if (pboardFormats == nullptr)
 142     {
 143         throw RuntimeException("Cannot get clipboard data", static_cast<XTransferable*>(this));
 144     }
 145
 146 #ifdef SAL_LOG_INFO
 147     NSString* types = @"";
 148     for (unsigned i = 0; i < [pboardFormats count]; i++)
 149     {
 150         if ([types length] > 0)
 151             types = [types stringByAppendingString:@", "];
 152         types = [types stringByAppendingString:[pboardFormats objectAtIndex:i]];
 153     }
 154     SAL_INFO("vcl.ios.clipboard", "Types on clipboard: " << [types UTF8String]);
 155 #endif
 156
 157     mFlavorList = mDataFlavorMapper->typesArrayToFlavorSequence(pboardFormats);
 158 }
 159
 160 /* Compares two DataFlavors. Returns true if both DataFlavor have the same media type
 161    and the number of parameter and all parameter values do match otherwise false
 162    is returned.
 163  */
 164 bool iOSTransferable::compareDataFlavors(const DataFlavor& lhs, const DataFlavor& rhs)
 165 {
 166     try
 167     {
 168         Reference<XMimeContentType> xLhs(mrXMimeCntFactory->createMimeContentType(lhs.MimeType));
 169         Reference<XMimeContentType> xRhs(mrXMimeCntFactory->createMimeContentType(rhs.MimeType));
 170
 171         if (!xLhs->getFullMediaType().equalsIgnoreAsciiCase(xRhs->getFullMediaType())
 172             || !cmpAllContentTypeParameter(xLhs, xRhs))
 173         {
 174             return false;
 175         }
 176     }
 177     catch (IllegalArgumentException&)
 178     {
 179         OSL_FAIL("Invalid content type detected");
 180         return false;
 181     }
 182
 183     return true;
 184 }
 185
 186 /* vim:set shiftwidth=4 softtabstop=4 expandtab: */