pkgs/games/sil/default.nix

   1 { pkgs, lib, stdenv, fetchzip, ncurses, libX11, libXaw, libXt, libXext, libXmu
   2 , makeWrapper, writeScript }:
   3
   4 let
   5   setup = writeScript "setup" ''
   6     mkdir -p "$ANGBAND_PATH"
   7     # Copy all the data files into place
   8     cp -ar $1/* "$ANGBAND_PATH"
   9     # The copied files are not writable, make them so
  10     chmod +w -R "$ANGBAND_PATH"
  11   '';
  12 in
  13 stdenv.mkDerivation rec {
  14   pname = "Sil";
  15   version = "1.3.0";
  16
  17   src = fetchzip {
  18     url = "https://www.amirrorclear.net/flowers/game/sil/Sil-130-src.zip";
  19     sha256 = "1amp2mr3fxascra0k76sdsvikjh8g76nqh46kka9379zd35lfq8w";
  20     stripRoot = false;
  21   };
  22
  23   nativeBuildInputs = [ makeWrapper ];
  24   buildInputs = [ ncurses libX11 libXaw libXt libXext libXmu ];
  25
  26   sourceRoot = "source/Sil/src";
  27
  28   makefile = "Makefile.std";
  29
  30   postPatch = ''
  31     # Allow usage of ANGBAND_PATH
  32     substituteInPlace config.h --replace "#define FIXED_PATHS" ""
  33   '';
  34
  35   preConfigure = ''
  36     buildFlagsArray+=("LIBS=-lXaw -lXext -lSM -lICE -lXmu -lXt -lX11 -lncurses")
  37   '';
  38
  39   # Workaround build failure on -fno-common toolchains like upstream
  40   # gcc-10. Otherwise build fails as:
  41   #   ld: main.o:/build/source/Sil/src/externs.h:57: multiple definition of
  42   #     `mini_screenshot_char'; variable.o:/build/source/Sil/src/externs.h:57: first defined here
  43   NIX_CFLAGS_COMPILE = "-fcommon";
  44
  45   installPhase = ''
  46     runHook preInstall
  47
  48     # the makefile doesn't have a sensible install target, so we have to do it ourselves
  49     mkdir -p $out/bin
  50     cp sil $out/bin/sil
  51
  52     # Wrap the program to set a user-local ANGBAND_PATH, and run the setup script to copy files into place.
  53     # We could just use the options for a user-local save and scores dir, but it tried to write to the
  54     # lib directory anyway, so we might as well give everyone a copy
  55     wrapProgram $out/bin/sil \
  56       --run "export ANGBAND_PATH=\$HOME/.sil" \
  57       --run "${setup} ${src}/Sil/lib"
  58
  59     runHook postInstall
  60   '';
  61
  62   passthru.tests = {
  63     saveDirCreation = pkgs.runCommand "save-dir-creation" {} ''
  64       HOME=$(pwd) ${lib.getExe pkgs.sil} --help
  65       test -d .sil && touch $out
  66     '';
  67   };
  68
  69   meta = {
  70     description = "A rogue-like game set in the First Age of Middle-earth";
  71     longDescription = ''
  72       A game of adventure set in the First Age of Middle-earth, when the world still
  73       rang with Elven song and gleamed with Dwarven mail.
  74
  75       Walk the dark halls of Angband.  Slay creatures black and fell.  Wrest a shining
  76       Silmaril from Morgoth’s iron crown.
  77     '';
  78     homepage = "http://www.amirrorclear.net/flowers/game/sil/index.html";
  79     license = lib.licenses.gpl2;
  80     maintainers = with lib.maintainers; [ michaelpj kenran ];
  81     platforms = lib.platforms.linux;
  82     mainProgram = "sil";
  83   };
  84 }