pkgs/applications/editors/kakoune/default.nix

   1 { lib, stdenv, fetchFromGitHub }:
   2
   3 stdenv.mkDerivation (finalAttrs: {
   4   pname = "kakoune-unwrapped";
   5   version = "2024.05.18";
   6   src = fetchFromGitHub {
   7     repo = "kakoune";
   8     owner = "mawww";
   9     rev = "v${finalAttrs.version}";
  10     hash = "sha256-1nYSVbvQ4tz1r8p7zCD6w/79haqpelb15qva9r3Fwew=";
  11   };
  12   makeFlags = [ "debug=no" "PREFIX=${placeholder "out"}" ];
  13
  14   postPatch = ''
  15     echo "v${finalAttrs.version}" >.version
  16   '';
  17
  18   enableParallelBuilding = true;
  19
  20   doInstallCheck = true;
  21   installCheckPhase = ''
  22     $out/bin/kak -ui json -e "kill 0"
  23   '';
  24
  25   postInstall = ''
  26     # make share/kak/autoload a directory, so we can use symlinkJoin with plugins
  27     cd "$out/share/kak"
  28     autoload_target=$(readlink autoload)
  29     rm autoload
  30     mkdir autoload
  31     ln -s --relative "$autoload_target" autoload
  32   '';
  33
  34   meta = with lib; {
  35     homepage = "http://kakoune.org/";
  36     description = "Vim inspired text editor";
  37     license = licenses.publicDomain;
  38     mainProgram = "kak";
  39     maintainers = with maintainers; [ philiptaron ];
  40     platforms = platforms.unix;
  41   };
  42 })