pkgs/applications/networking/davmail/default.nix

   1 { stdenv
   2 , fetchurl
   3 , lib
   4 , makeWrapper
   5 , unzip
   6 , glib
   7 , gtk2
   8 , gtk3
   9 , jre
  10 , libXtst
  11 , coreutils
  12 , gnugrep
  13 , zulu
  14 , preferGtk3 ? true
  15 , preferZulu ? true
  16 }:
  17
  18 let
  19   rev = 3546;
  20   jre' = if preferZulu then zulu else jre;
  21   gtk' = if preferGtk3 then gtk3 else gtk2;
  22 in
  23 stdenv.mkDerivation rec {
  24   pname = "davmail";
  25   version = "6.2.2";
  26
  27   src = fetchurl {
  28     url = "mirror://sourceforge/${pname}/${version}/${pname}-${version}-${toString rev}.zip";
  29     hash = "sha256-45paGy6SfUFXK6vY8L4tHFYiio1/5ah9vTyGImdgwHI=";
  30   };
  31
  32   postPatch = ''
  33     sed -i -e '/^JAVA_OPTS/d' davmail
  34   '';
  35
  36   sourceRoot = ".";
  37
  38   nativeBuildInputs = [ makeWrapper unzip ];
  39
  40   installPhase = ''
  41     runHook preInstall
  42
  43     mkdir -p $out/share/davmail
  44     cp -vR ./* $out/share/davmail
  45     makeWrapper $out/share/davmail/davmail $out/bin/davmail \
  46       --set-default JAVA_OPTS "-Xmx512M -Dsun.net.inetaddr.ttl=60 -Djdk.gtk.version=${lib.versions.major gtk'.version}" \
  47       --prefix PATH : ${lib.makeBinPath [ jre' coreutils gnugrep ]} \
  48       --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ glib gtk' libXtst ]}
  49
  50     runHook postInstall
  51   '';
  52
  53   meta = with lib; {
  54     description = "Java application which presents a Microsoft Exchange server as local CALDAV, IMAP and SMTP servers";
  55     homepage = "https://davmail.sourceforge.net/";
  56     license = licenses.gpl2Plus;
  57     maintainers = with maintainers; [ peterhoeg ];
  58     platforms = platforms.all;
  59     mainProgram = "davmail";
  60   };
  61 }