pkgs/build-support/agda/default.nix

   1 # Builder for Agda packages.
   2
   3 { stdenv, lib, self, Agda, runCommand, makeWrapper, writeText, ghcWithPackages, nixosTests }:
   4
   5 let
   6   inherit (lib)
   7     attrValues
   8     elem
   9     filter
  10     filterAttrs
  11     isAttrs
  12     isList
  13     platforms
  14     ;
  15
  16   inherit (lib.strings)
  17     concatMapStrings
  18     concatMapStringsSep
  19     optionalString
  20     ;
  21
  22   mkLibraryFile = pkgs: let
  23     pkgs' = if isList pkgs then pkgs else pkgs self;
  24   in writeText "libraries" ''
  25     ${(concatMapStringsSep "\n" (p: "${p}/${p.libraryFile}") pkgs')}
  26   '';
  27
  28   withPackages' = {
  29     pkgs,
  30     ghc ? ghcWithPackages (p: with p; [ ieee754 ])
  31   }: let
  32     library-file = mkLibraryFile pkgs;
  33     pname = "agdaWithPackages";
  34     version = Agda.version;
  35   in runCommand "${pname}-${version}" {
  36     inherit pname version;
  37     nativeBuildInputs = [ makeWrapper ];
  38     passthru = {
  39       unwrapped = Agda;
  40       inherit withPackages;
  41       tests = {
  42         inherit (nixosTests) agda;
  43         allPackages = withPackages (filter self.lib.isUnbrokenAgdaPackage (attrValues self));
  44       };
  45     };
  46     # Agda is a split package with multiple outputs; do not inherit them here.
  47     meta = removeAttrs Agda.meta [ "outputsToInstall" ];
  48   } ''
  49     mkdir -p $out/bin
  50     makeWrapper ${Agda.bin}/bin/agda $out/bin/agda \
  51       --add-flags "--with-compiler=${ghc}/bin/ghc" \
  52       --add-flags "--library-file=${library-file}"
  53     ln -s ${Agda.bin}/bin/agda-mode $out/bin/agda-mode
  54     '';
  55
  56   withPackages = arg: if isAttrs arg then withPackages' arg else withPackages' { pkgs = arg; };
  57
  58   extensions = [
  59     "agda"
  60     "agda-lib"
  61     "agdai"
  62     "lagda"
  63     "lagda.md"
  64     "lagda.org"
  65     "lagda.rst"
  66     "lagda.tex"
  67     "lagda.typ"
  68   ];
  69
  70   defaults =
  71     { pname
  72     , meta
  73     , buildInputs ? []
  74     , everythingFile ? "./Everything.agda"
  75     , includePaths ? []
  76     , libraryName ? pname
  77     , libraryFile ? "${libraryName}.agda-lib"
  78     , buildPhase ? null
  79     , installPhase ? null
  80     , extraExtensions ? []
  81     , ...
  82     }: let
  83       agdaWithArgs = withPackages (filter (p: p ? isAgdaDerivation) buildInputs);
  84       includePathArgs = concatMapStrings (path: "-i" + path + " ") (includePaths ++ [(dirOf everythingFile)]);
  85     in
  86       {
  87         inherit libraryName libraryFile;
  88
  89         isAgdaDerivation = true;
  90
  91         buildInputs = buildInputs ++ [ agdaWithArgs ];
  92
  93         buildPhase = if buildPhase != null then buildPhase else ''
  94           runHook preBuild
  95           agda ${includePathArgs} ${everythingFile}
  96           rm ${everythingFile} ${lib.interfaceFile Agda.version everythingFile}
  97           runHook postBuild
  98         '';
  99
 100         installPhase = if installPhase != null then installPhase else ''
 101           runHook preInstall
 102           mkdir -p $out
 103           find \( ${concatMapStringsSep " -or " (p: "-name '*.${p}'") (extensions ++ extraExtensions)} \) -exec cp -p --parents -t "$out" {} +
 104           runHook postInstall
 105         '';
 106
 107         # As documented at https://github.com/NixOS/nixpkgs/issues/172752,
 108         # we need to set LC_ALL to an UTF-8-supporting locale. However, on
 109         # darwin, it seems that there is no standard such locale; luckily,
 110         # the referenced issue doesn't seem to surface on darwin. Hence let's
 111         # set this only on non-darwin.
 112         LC_ALL = optionalString (!stdenv.hostPlatform.isDarwin) "C.UTF-8";
 113
 114         meta = if meta.broken or false then meta // { hydraPlatforms = platforms.none; } else meta;
 115
 116         # Retrieve all packages from the finished package set that have the current package as a dependency and build them
 117         passthru.tests =
 118           filterAttrs (name: pkg: self.lib.isUnbrokenAgdaPackage pkg && elem pname (map (pkg: pkg.pname) pkg.buildInputs)) self;
 119       };
 120 in
 121 {
 122   mkDerivation = args: stdenv.mkDerivation (args // defaults args);
 123
 124   inherit mkLibraryFile withPackages withPackages';
 125 }