pkgs/build-support/buildenv/default.nix

   1 # buildEnv creates a tree of symlinks to the specified paths.  This is
   2 # a fork of the hardcoded buildEnv in the Nix distribution.
   3
   4 { buildPackages, runCommand, lib, substituteAll, writeClosure }:
   5
   6 let
   7   builder = substituteAll {
   8     src = ./builder.pl;
   9     inherit (builtins) storeDir;
  10   };
  11 in
  12
  13 lib.makeOverridable
  14 ({ name
  15
  16 , # The manifest file (if any).  A symlink $out/manifest will be
  17   # created to it.
  18   manifest ? ""
  19
  20 , # The paths to symlink.
  21   paths
  22
  23 , # Whether to ignore collisions or abort.
  24   ignoreCollisions ? false
  25
  26 , # Whether to include closures of all input paths.
  27   includeClosures ? false
  28
  29 , # If there is a collision, check whether the contents and permissions match
  30   # and only if not, throw a collision error.
  31   checkCollisionContents ? true
  32
  33 , # The paths (relative to each element of `paths') that we want to
  34   # symlink (e.g., ["/bin"]).  Any file not inside any of the
  35   # directories in the list is not symlinked.
  36   pathsToLink ? ["/"]
  37
  38 , # The package outputs to include. By default, only the default
  39   # output is included.
  40   extraOutputsToInstall ? []
  41
  42 , # Root the result in directory "$out${extraPrefix}", e.g. "/share".
  43   extraPrefix ? ""
  44
  45 , # Shell commands to run after building the symlink tree.
  46   postBuild ? ""
  47
  48 # Additional inputs
  49 , nativeBuildInputs ? [] # Handy e.g. if using makeWrapper in `postBuild`.
  50 , buildInputs ? []
  51
  52 , passthru ? {}
  53 , meta ? {}
  54 }:
  55 let
  56   chosenOutputs = map (drv: {
  57     paths =
  58       # First add the usual output(s): respect if user has chosen explicitly,
  59       # and otherwise use `meta.outputsToInstall`. The attribute is guaranteed
  60       # to exist in mkDerivation-created cases. The other cases (e.g. runCommand)
  61       # aren't expected to have multiple outputs.
  62       (if (! drv ? outputSpecified || ! drv.outputSpecified)
  63           && drv.meta.outputsToInstall or null != null
  64         then map (outName: drv.${outName}) drv.meta.outputsToInstall
  65         else [ drv ])
  66       # Add any extra outputs specified by the caller of `buildEnv`.
  67       ++ lib.filter (p: p!=null)
  68         (builtins.map (outName: drv.${outName} or null) extraOutputsToInstall);
  69     priority = drv.meta.priority or lib.meta.defaultPriority;
  70   }) paths;
  71
  72   pathsForClosure = lib.pipe chosenOutputs [
  73     (map (p: p.paths))
  74     lib.flatten
  75     (lib.remove null)
  76   ];
  77 in runCommand name
  78   rec {
  79     inherit manifest ignoreCollisions checkCollisionContents passthru
  80             meta pathsToLink extraPrefix postBuild
  81             nativeBuildInputs buildInputs;
  82     pkgs = builtins.toJSON chosenOutputs;
  83     extraPathsFrom = lib.optional includeClosures (writeClosure pathsForClosure);
  84     preferLocalBuild = true;
  85     allowSubstitutes = false;
  86     # XXX: The size is somewhat arbitrary
  87     passAsFile = if builtins.stringLength pkgs >= 128*1024 then [ "pkgs" ] else [ ];
  88   }
  89   ''
  90     ${buildPackages.perl}/bin/perl -w ${builder}
  91     eval "$postBuild"
  92   '')