pkgs/tools/misc/xvfb-run/default.nix

   1 { lib
   2 , stdenvNoCC
   3 , fetchFromGitHub
   4 , makeWrapper
   5 , xorg
   6 , getopt
   7 , xauth
   8 , util-linux
   9 , which
  10 , fontsConf
  11 , gawk
  12 , coreutils
  13 , installShellFiles
  14 , xterm
  15 }:
  16 stdenvNoCC.mkDerivation rec {
  17   pname = "xvfb-run";
  18   version = "1+g87f6705";
  19
  20   src = fetchFromGitHub {
  21     owner = "archlinux";
  22     repo = "svntogit-packages";
  23     rev = "87f67054c49b32511893acd22be94c47ecd44b4a";
  24     sha256 = "sha256-KEg92RYgJd7naHFDKbdXEy075bt6NLcmX8VhQROHVPs=";
  25   };
  26
  27   nativeBuildInputs = [ makeWrapper installShellFiles ];
  28
  29   dontUnpack = true;
  30   dontBuild = true;
  31   dontConfigure = true;
  32
  33   installPhase = ''
  34     mkdir -p $out/bin
  35     cp $src/trunk/xvfb-run $out/bin/xvfb-run
  36     installManPage $src/trunk/xvfb-run.1
  37
  38     chmod a+x $out/bin/xvfb-run
  39     patchShebangs $out/bin/xvfb-run
  40     wrapProgram $out/bin/xvfb-run \
  41       --set-default FONTCONFIG_FILE "${fontsConf}" \
  42       --prefix PATH : ${lib.makeBinPath [ getopt xorg.xvfb xauth which util-linux gawk coreutils ]}
  43   '';
  44
  45   doInstallCheck = true;
  46   installCheckPhase = ''
  47     (
  48       unset PATH
  49       echo "running xterm with xvfb-run"
  50       $out/bin/xvfb-run ${lib.getBin xterm}/bin/xterm -e true
  51     )
  52   '';
  53
  54   passthru = {
  55     updateScript = ./update.sh;
  56   };
  57
  58   meta = with lib; {
  59     description = "Convenience script to run a virtualized X-Server";
  60     platforms = platforms.linux;
  61     license = licenses.gpl2Only;
  62     maintainers = [ maintainers.artturin ];
  63     mainProgram = "xvfb-run";
  64   };
  65 }