pkgs/desktops/gnome/misc/gnome-panel/wrapper.nix

   1 { stdenv
   2 , lib
   3 , buildEnv
   4 , gnome-panel
   5 , gnome-flashback
   6 , xorg
   7 , glib
   8 , wrapGAppsHook3
   9 , panelModulePackages ? [ ]
  10 }:
  11
  12 let
  13   # We always want to find the built-in panel applets.
  14   selectedPanelModulePackages = [ gnome-panel gnome-flashback ] ++ panelModulePackages;
  15
  16   panelModulesEnv = buildEnv {
  17     name = "gnome-panel-modules-env";
  18     paths = selectedPanelModulePackages;
  19     pathsToLink = [ "/lib/gnome-panel/modules" ];
  20   };
  21 in
  22 stdenv.mkDerivation {
  23   pname = "${gnome-panel.pname}-with-modules";
  24   inherit (gnome-panel) version;
  25
  26   nativeBuildInputs = [
  27     glib
  28     wrapGAppsHook3
  29   ];
  30
  31   buildInputs = selectedPanelModulePackages ++
  32     lib.forEach selectedPanelModulePackages (x: x.buildInputs or [ ]);
  33
  34   dontUnpack = true;
  35   dontConfigure = true;
  36   dontBuild = true;
  37
  38   preferLocalBuild = true;
  39   allowSubstitutes = false;
  40
  41   installPhase = ''
  42     runHook preInstall
  43
  44     mkdir -p $out
  45     ${xorg.lndir}/bin/lndir -silent ${gnome-panel} $out
  46
  47     rm -r $out/lib/gnome-panel/modules
  48     ${xorg.lndir}/bin/lndir -silent ${panelModulesEnv} $out
  49
  50     rm $out/share/applications/gnome-panel.desktop
  51
  52     substitute ${gnome-panel}/share/applications/gnome-panel.desktop \
  53       $out/share/applications/gnome-panel.desktop --replace \
  54       "Exec=${gnome-panel}/bin/gnome-panel" "Exec=$out/bin/gnome-panel"
  55
  56     runHook postInstall
  57   '';
  58
  59   preFixup = ''
  60     gappsWrapperArgs+=(
  61       --set NIX_GNOME_PANEL_MODULESDIR "$out/lib/gnome-panel/modules"
  62     )
  63   '';
  64
  65   meta = gnome-panel.meta // { outputsToInstall = [ "out" ]; };
  66 }