pkgs/servers/dns/knot-dns/default.nix

   1 { lib, stdenv, fetchurl, pkg-config, gnutls, liburcu, lmdb, libcap_ng, libidn2, libunistring
   2 , systemd, nettle, libedit, zlib, libiconv, libintl, libmaxminddb, libbpf, nghttp2, libmnl
   3 , ngtcp2-gnutls, xdp-tools
   4 , autoreconfHook
   5 , nixosTests, knot-resolver, knot-dns, runCommandLocal
   6 }:
   7
   8 stdenv.mkDerivation rec {
   9   pname = "knot-dns";
  10   version = "3.3.8";
  11
  12   src = fetchurl {
  13     url = "https://secure.nic.cz/files/knot-dns/knot-${version}.tar.xz";
  14     sha256 = "498de8338489a625673797f7ecc921fa4490c826afbfa42fa66922b525089e6a";
  15   };
  16
  17   outputs = [ "bin" "out" "dev" ];
  18
  19   configureFlags = [
  20     "--with-configdir=/etc/knot"
  21     "--with-rundir=/run/knot"
  22     "--with-storage=/var/lib/knot"
  23   ];
  24
  25   patches = [
  26     # Don't try to create directories like /var/lib/knot at build time.
  27     # They are later created from NixOS itself.
  28     ./dont-create-run-time-dirs.patch
  29     ./runtime-deps.patch
  30   ];
  31
  32   nativeBuildInputs = [ pkg-config autoreconfHook ];
  33   buildInputs = [
  34     gnutls liburcu libidn2 libunistring
  35     nettle libedit
  36     libiconv lmdb libintl
  37     nghttp2 # DoH support in kdig
  38     ngtcp2-gnutls  # DoQ support in kdig (and elsewhere but not much use there yet)
  39     libmaxminddb # optional for geoip module (it's tiny)
  40     # without sphinx &al. for developer documentation
  41     # TODO: add dnstap support?
  42   ] ++ lib.optionals stdenv.isLinux [
  43     libcap_ng systemd
  44     xdp-tools libbpf libmnl # XDP support (it's Linux kernel API)
  45   ] ++ lib.optional stdenv.isDarwin zlib; # perhaps due to gnutls
  46
  47   enableParallelBuilding = true;
  48
  49   CFLAGS = [ "-O2" "-DNDEBUG" ];
  50
  51   doCheck = true;
  52   checkFlags = [ "V=1" ]; # verbose output in case some test fails
  53   doInstallCheck = true;
  54
  55   postInstall = ''
  56     rm -r "$out"/lib/*.la
  57   '';
  58
  59   passthru.tests = {
  60     inherit knot-resolver;
  61   } // lib.optionalAttrs stdenv.isLinux {
  62     inherit (nixosTests) knot kea;
  63     prometheus-exporter = nixosTests.prometheus-exporters.knot;
  64     # Some dependencies are very version-sensitive, so the might get dropped
  65     # or embedded after some update, even if the nixPackagers didn't intend to.
  66     # For non-linux I don't know a good replacement for `ldd`.
  67     deps = runCommandLocal "knot-deps-test"
  68       { nativeBuildInputs = [ (lib.getBin stdenv.cc.libc) ]; }
  69       ''
  70         for libname in libngtcp2 libxdp libbpf; do
  71           echo "Checking for $libname:"
  72           ldd '${knot-dns.bin}/bin/knotd' | grep -F "$libname"
  73           echo "OK"
  74         done
  75         touch "$out"
  76       '';
  77   };
  78
  79   meta = with lib; {
  80     description = "Authoritative-only DNS server from .cz domain registry";
  81     homepage = "https://knot-dns.cz";
  82     license = licenses.gpl3Plus;
  83     platforms = platforms.unix;
  84     maintainers = [ maintainers.vcunat ];
  85     mainProgram = "knotd";
  86   };
  87 }