pkgs/servers/firebird/default.nix

   1 { lib, stdenv, fetchFromGitHub, libedit, autoreconfHook271, zlib, unzip, libtommath, libtomcrypt, icu, superServer ? false }:
   2
   3 let base = {
   4   pname = "firebird";
   5
   6   meta = with lib; {
   7     description = "SQL relational database management system";
   8     downloadPage = "https://github.com/FirebirdSQL/firebird/";
   9     homepage = "https://firebirdsql.org/";
  10     changelog = "https://github.com/FirebirdSQL/firebird/blob/master/CHANGELOG.md";
  11     license = [ "IDPL" "Interbase-1.0" ];
  12     platforms = platforms.linux;
  13     maintainers = with maintainers; [ marcweber ];
  14   };
  15
  16   nativeBuildInputs = [ autoreconfHook271 ];
  17
  18   buildInputs = [ libedit icu ];
  19
  20   LD_LIBRARY_PATH = lib.makeLibraryPath [ icu ];
  21
  22   configureFlags = [
  23     "--with-system-editline"
  24   ] ++ (lib.optional superServer "--enable-superserver");
  25
  26   installPhase = ''
  27     runHook preInstall
  28     mkdir -p $out
  29     cp -r gen/Release/firebird/* $out
  30     runHook postInstall
  31   '';
  32
  33 }; in rec {
  34
  35   firebird_2_5 = stdenv.mkDerivation (base // rec {
  36     version = "2.5.9";
  37
  38     src = fetchFromGitHub {
  39       owner = "FirebirdSQL";
  40       repo = "firebird";
  41       rev = "R${builtins.replaceStrings [ "." ] [ "_" ] version}";
  42       sha256 = "sha256-YyvlMeBux80OpVhsCv+6IVxKXFRsgdr+1siupMR13JM=";
  43     };
  44
  45     configureFlags = base.configureFlags ++ [ "--with-system-icu" ];
  46
  47     installPhase = ''
  48       runHook preInstall
  49       mkdir -p $out
  50       cp -r gen/firebird/* $out
  51       runHook postInstall
  52     '';
  53
  54     meta = base.meta // { platforms = [ "x86_64-linux" ]; };
  55   });
  56
  57   firebird_3 = stdenv.mkDerivation (base // rec {
  58     version = "3.0.10";
  59
  60     src = fetchFromGitHub {
  61       owner = "FirebirdSQL";
  62       repo = "firebird";
  63       rev = "v${version}";
  64       sha256 = "sha256-PT2b3989n/7xLGNREWinEey9SGnAXShITdum+yiFlHY=";
  65     };
  66
  67     buildInputs = base.buildInputs ++ [ zlib libtommath ];
  68
  69     meta = base.meta // { platforms = [ "x86_64-linux" ]; };
  70   });
  71
  72   firebird_4 = stdenv.mkDerivation (base // rec {
  73     version = "4.0.2";
  74
  75     src = fetchFromGitHub {
  76       owner = "FirebirdSQL";
  77       repo = "firebird";
  78       rev = "v${version}";
  79       sha256 = "sha256-hddW/cozboGw693q4k5f4+x9ccQFWFytXPUaBVkFnL4=";
  80     };
  81
  82     buildInputs = base.buildInputs ++ [ zlib unzip libtommath libtomcrypt ];
  83   });
  84
  85   firebird = firebird_4;
  86 }