pkgs/servers/monitoring/prometheus/php-fpm-exporter.nix

   1 { lib
   2 , buildGoModule
   3 , fetchFromGitHub
   4 , makeWrapper
   5 , installShellFiles
   6 , getent
   7 , nix-update-script
   8 , testers
   9 , prometheus-php-fpm-exporter
  10 }:
  11
  12 buildGoModule rec {
  13   pname = "php-fpm_exporter";
  14   version = "2.2.0";
  15
  16   src = fetchFromGitHub {
  17     owner = "hipages";
  18     repo = pname;
  19     rev = "v${version}";
  20     hash = "sha256-ggrFnyEdGBoZVh4dHMw+7RUm8nJ1hJXo/fownO3wvzE=";
  21   };
  22
  23   vendorHash = "sha256-OK36tHkBtosdfEWFPYMtlbzCkh5cF35NBWYyJrb9fwg=";
  24
  25   nativeBuildInputs = [ makeWrapper installShellFiles ];
  26
  27   ldflags = [
  28     "-X main.version=${version}"
  29   ];
  30
  31   preFixup = ''
  32     wrapProgram "$out/bin/php-fpm_exporter" \
  33       --prefix PATH ":" "${lib.makeBinPath [ getent ]}"
  34   '';
  35
  36   postInstall = ''
  37     installShellCompletion --cmd php-fpm_exporter \
  38       --bash <($out/bin/php-fpm_exporter completion bash) \
  39       --fish <($out/bin/php-fpm_exporter completion fish) \
  40       --zsh <($out/bin/php-fpm_exporter completion zsh)
  41   '';
  42
  43   passthru = {
  44     updateScript = nix-update-script { };
  45     tests = testers.testVersion {
  46       inherit version;
  47       package = prometheus-php-fpm-exporter;
  48       command = "php-fpm_exporter version";
  49     };
  50   };
  51
  52   meta = with lib; {
  53     homepage = "https://github.com/hipages/php-fpm_exporter";
  54     description = "Prometheus exporter for PHP-FPM";
  55     license = licenses.asl20;
  56     maintainers = with maintainers; [ gaelreyrol ];
  57     mainProgram = "php-fpm_exporter";
  58   };
  59 }