nixos/tests/filesystems-overlayfs.nix

   1 { lib, pkgs, ... }:
   2
   3 let
   4   initrdLowerdir = pkgs.runCommand "initrd-lowerdir" { } ''
   5     mkdir -p $out
   6     echo "initrd" > $out/initrd.txt
   7   '';
   8   initrdLowerdir2 = pkgs.runCommand "initrd-lowerdir-2" { } ''
   9     mkdir -p $out
  10     echo "initrd2" > $out/initrd2.txt
  11   '';
  12   userspaceLowerdir = pkgs.runCommand "userspace-lowerdir" { } ''
  13     mkdir -p $out
  14     echo "userspace" > $out/userspace.txt
  15   '';
  16   userspaceLowerdir2 = pkgs.runCommand "userspace-lowerdir-2" { } ''
  17     mkdir -p $out
  18     echo "userspace2" > $out/userspace2.txt
  19   '';
  20 in
  21 {
  22
  23   name = "writable-overlays";
  24
  25   meta.maintainers = with lib.maintainers; [ nikstur ];
  26
  27   nodes.machine = { config, pkgs, ... }: {
  28     boot.initrd.systemd.enable = true;
  29
  30     virtualisation.fileSystems = {
  31       "/initrd-overlay" = {
  32         overlay = {
  33           lowerdir = [ initrdLowerdir ];
  34           upperdir = "/.rw-initrd-overlay/upper";
  35           workdir = "/.rw-initrd-overlay/work";
  36         };
  37         neededForBoot = true;
  38       };
  39       "/userspace-overlay" = {
  40         overlay = {
  41           lowerdir = [ userspaceLowerdir ];
  42           upperdir = "/.rw-userspace-overlay/upper";
  43           workdir = "/.rw-userspace-overlay/work";
  44         };
  45       };
  46       "/ro-initrd-overlay" = {
  47         overlay.lowerdir = [
  48           initrdLowerdir
  49           initrdLowerdir2
  50         ];
  51         neededForBoot = true;
  52       };
  53       "/ro-userspace-overlay" = {
  54         overlay.lowerdir = [
  55           userspaceLowerdir
  56           userspaceLowerdir2
  57         ];
  58       };
  59     };
  60   };
  61
  62   testScript = ''
  63     machine.wait_for_unit("default.target")
  64
  65     with subtest("Initrd overlay"):
  66       machine.wait_for_file("/initrd-overlay/initrd.txt", 5)
  67       machine.succeed("touch /initrd-overlay/writable.txt")
  68       machine.succeed("findmnt --kernel --types overlay /initrd-overlay")
  69
  70     with subtest("Userspace overlay"):
  71       machine.wait_for_file("/userspace-overlay/userspace.txt", 5)
  72       machine.succeed("touch /userspace-overlay/writable.txt")
  73       machine.succeed("findmnt --kernel --types overlay /userspace-overlay")
  74
  75     with subtest("Read only initrd overlay"):
  76       machine.wait_for_file("/ro-initrd-overlay/initrd.txt", 5)
  77       machine.wait_for_file("/ro-initrd-overlay/initrd2.txt", 5)
  78       machine.fail("touch /ro-initrd-overlay/not-writable.txt")
  79       machine.succeed("findmnt --kernel --types overlay /ro-initrd-overlay")
  80
  81     with subtest("Read only userspace overlay"):
  82       machine.wait_for_file("/ro-userspace-overlay/userspace.txt", 5)
  83       machine.wait_for_file("/ro-userspace-overlay/userspace2.txt", 5)
  84       machine.fail("touch /ro-userspace-overlay/not-writable.txt")
  85       machine.succeed("findmnt --kernel --types overlay /ro-userspace-overlay")
  86   '';
  87
  88 }