nixos/tests/postgresql-wal2json.nix

   1 {
   2   system ? builtins.currentSystem,
   3   config ? { },
   4   pkgs ? import ../.. { inherit system config; },
   5   postgresql ? null,
   6 }:
   7
   8 let
   9   makeTest = import ./make-test-python.nix;
  10   # Makes a test for a PostgreSQL package, given by name and looked up from `pkgs`.
  11   makeTestAttribute = name: {
  12     inherit name;
  13     value = makePostgresqlWal2jsonTest pkgs."${name}";
  14   };
  15
  16   makePostgresqlWal2jsonTest =
  17     postgresqlPackage:
  18     makeTest {
  19       name = "postgresql-wal2json-${postgresqlPackage.name}";
  20       meta.maintainers = with pkgs.lib.maintainers; [ euank ];
  21
  22       nodes.machine = {
  23         services.postgresql = {
  24           package = postgresqlPackage;
  25           enable = true;
  26           extraPlugins = with postgresqlPackage.pkgs; [ wal2json ];
  27           settings = {
  28             wal_level = "logical";
  29             max_replication_slots = "10";
  30             max_wal_senders = "10";
  31           };
  32         };
  33       };
  34
  35       testScript = ''
  36         machine.wait_for_unit("postgresql")
  37         machine.succeed(
  38             "sudo -u postgres psql -qAt -f ${./postgresql/wal2json/example2.sql} postgres > /tmp/example2.out"
  39         )
  40         machine.succeed(
  41             "diff ${./postgresql/wal2json/example2.out} /tmp/example2.out"
  42         )
  43         machine.succeed(
  44             "sudo -u postgres psql -qAt -f ${./postgresql/wal2json/example3.sql} postgres > /tmp/example3.out"
  45         )
  46         machine.succeed(
  47             "diff ${./postgresql/wal2json/example3.out} /tmp/example3.out"
  48         )
  49       '';
  50     };
  51
  52 in
  53 # By default, create one test per postgresql version
  54 if postgresql == null then
  55   builtins.listToAttrs (
  56     map makeTestAttribute (builtins.attrNames (import ../../pkgs/servers/sql/postgresql pkgs))
  57   )
  58 # but if postgresql is set, we're being made as a passthru test for a specific postgres + wal2json version, just run one
  59 else
  60   makePostgresqlWal2jsonTest postgresql