pkgs/by-name/ta/taskwarrior2/package.nix

   1 {
   2   lib,
   3   stdenv,
   4   fetchFromGitHub,
   5   cmake,
   6   libuuid,
   7   gnutls,
   8   python3,
   9   xdg-utils,
  10   installShellFiles,
  11 }:
  12
  13 stdenv.mkDerivation rec {
  14   pname = "taskwarrior";
  15   version = "2.6.2";
  16
  17   src = fetchFromGitHub {
  18     owner = "GothenburgBitFactory";
  19     repo = "taskwarrior";
  20     rev = "v${version}";
  21     hash = "sha256-0YveqiylXJi4cdDCfnPtwCVOJbQrZYsxnXES+9B4Yfw=";
  22     fetchSubmodules = true;
  23   };
  24
  25   postPatch = ''
  26     substituteInPlace src/commands/CmdNews.cpp \
  27       --replace "xdg-open" "${lib.getBin xdg-utils}/bin/xdg-open"
  28   '';
  29
  30   nativeBuildInputs = [
  31     cmake
  32     libuuid
  33     gnutls
  34     python3
  35     installShellFiles
  36   ];
  37
  38   doCheck = true;
  39   preCheck = ''
  40     patchShebangs --build test
  41   '';
  42   checkTarget = "test";
  43
  44   postInstall = ''
  45     # ZSH is installed automatically from some reason, only bash and fish need
  46     # manual installation
  47     installShellCompletion --cmd task \
  48       --bash $out/share/doc/task/scripts/bash/task.sh \
  49       --fish $out/share/doc/task/scripts/fish/task.fish
  50     rm -r $out/share/doc/task/scripts/bash
  51     rm -r $out/share/doc/task/scripts/fish
  52     # Install vim and neovim plugin
  53     mkdir -p $out/share/vim-plugins
  54     mv $out/share/doc/task/scripts/vim $out/share/vim-plugins/task
  55     mkdir -p $out/share/nvim
  56     ln -s $out/share/vim-plugins/task $out/share/nvim/site
  57   '';
  58
  59   meta = with lib; {
  60     description = "Highly flexible command-line tool to manage TODO lists";
  61     homepage = "https://taskwarrior.org";
  62     license = licenses.mit;
  63     maintainers = with maintainers; [
  64       marcweber
  65       oxalica
  66     ];
  67     mainProgram = "task";
  68     platforms = platforms.unix;
  69   };
  70 }