pkgs/by-name/xw/xwayland-run/package.nix

   1 { fetchFromGitLab
   2 , lib
   3 , meson
   4 , ninja
   5 , python3
   6 , weston
   7 , xorg
   8 , xwayland
   9 , withCage ? false , cage
  10 , withKwin ? false , kdePackages
  11 , withMutter ? false, gnome
  12 , withDbus ? withMutter , dbus # Since 0.0.3, mutter compositors run with their own DBUS sessions
  13 }:
  14 let
  15   compositors = [ weston ]
  16     ++ lib.optional withCage cage
  17     ++ lib.optional withKwin kdePackages.kwin
  18     ++ lib.optional withMutter gnome.mutter ++ lib.optional withDbus dbus
  19   ;
  20 in
  21 python3.pkgs.buildPythonApplication rec {
  22   pname = "xwayland-run";
  23   version = "0.0.4";
  24
  25   src = fetchFromGitLab {
  26     domain = "gitlab.freedesktop.org";
  27     owner = "ofourdan";
  28     repo = "xwayland-run";
  29     rev = version;
  30     hash = "sha256-FP/2KNPehZEGKXr+fKdVj4DXzRMpfc3x7K6vH6ZsGdo=";
  31   };
  32
  33   pyproject = false;
  34
  35   outputs = [ "out" "man" ];
  36
  37   nativeBuildInputs = [
  38     meson
  39     ninja
  40   ];
  41
  42   postInstall = ''
  43     wrapProgram $out/bin/wlheadless-run \
  44       --prefix PATH : ${lib.makeBinPath compositors}
  45     wrapProgram $out/bin/xwayland-run \
  46       --prefix PATH : ${lib.makeBinPath [ xwayland xorg.xauth ]}
  47     wrapProgram $out/bin/xwfb-run \
  48       --prefix PATH : ${lib.makeBinPath (compositors ++ [ xwayland xorg.xauth ])}
  49   '';
  50
  51   meta = {
  52     changelog = "https://gitlab.freedesktop.org/ofourdan/xwayland-run/-/releases/${src.rev}";
  53     description = "Set of small utilities revolving around running Xwayland and various Wayland compositor headless";
  54     homepage = "https://gitlab.freedesktop.org/ofourdan/xwayland-run";
  55     license = lib.licenses.gpl2Only;
  56     maintainers = with lib.maintainers; [ arthsmn ];
  57     platforms = lib.platforms.linux;
  58   };
  59 }