nixos/modules/services/hardware/pcscd.nix

   1 { config, lib, pkgs, ... }:
   2
   3 with lib;
   4
   5 let
   6   cfgFile = pkgs.writeText "reader.conf" config.services.pcscd.readerConfig;
   7
   8   package = if config.security.polkit.enable
   9               then pkgs.pcscliteWithPolkit
  10               else pkgs.pcsclite;
  11
  12   pluginEnv = pkgs.buildEnv {
  13     name = "pcscd-plugins";
  14     paths = map (p: "${p}/pcsc/drivers") config.services.pcscd.plugins;
  15   };
  16
  17 in
  18 {
  19
  20   ###### interface
  21
  22   options.services.pcscd = {
  23     enable = mkEnableOption (lib.mdDoc "PCSC-Lite daemon");
  24
  25     plugins = mkOption {
  26       type = types.listOf types.package;
  27       defaultText = literalExpression "[ pkgs.ccid ]";
  28       example = literalExpression "[ pkgs.pcsc-cyberjack ]";
  29       description = lib.mdDoc "Plugin packages to be used for PCSC-Lite.";
  30     };
  31
  32     readerConfig = mkOption {
  33       type = types.lines;
  34       default = "";
  35       example = ''
  36         FRIENDLYNAME      "Some serial reader"
  37         DEVICENAME        /dev/ttyS0
  38         LIBPATH           /path/to/serial_reader.so
  39         CHANNELID         1
  40       '';
  41       description = lib.mdDoc ''
  42         Configuration for devices that aren't hotpluggable.
  43
  44         See {manpage}`reader.conf(5)` for valid options.
  45       '';
  46     };
  47   };
  48
  49   ###### implementation
  50
  51   config = mkIf config.services.pcscd.enable {
  52
  53     environment.etc."reader.conf".source = cfgFile;
  54
  55     environment.systemPackages = [ package ];
  56     systemd.packages = [ (getBin package) ];
  57
  58     services.pcscd.plugins = [ pkgs.ccid ];
  59
  60     systemd.sockets.pcscd.wantedBy = [ "sockets.target" ];
  61
  62     systemd.services.pcscd = {
  63       environment.PCSCLITE_HP_DROPDIR = pluginEnv;
  64       restartTriggers = [ "/etc/reader.conf" ];
  65
  66       # If the cfgFile is empty and not specified (in which case the default
  67       # /etc/reader.conf is assumed), pcscd will happily start going through the
  68       # entire confdir (/etc in our case) looking for a config file and try to
  69       # parse everything it finds. Doesn't take a lot of imagination to see how
  70       # well that works. It really shouldn't do that to begin with, but to work
  71       # around it, we force the path to the cfgFile.
  72       #
  73       # https://github.com/NixOS/nixpkgs/issues/121088
  74       serviceConfig.ExecStart = [ "" "${getBin package}/bin/pcscd -f -x -c ${cfgFile}" ];
  75     };
  76   };
  77 }