pkgs/development/rocm-modules/5/rocprim/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , rocmUpdateScript
   5 , cmake
   6 , rocm-cmake
   7 , clr
   8 , gtest
   9 , gbenchmark
  10 , buildTests ? false
  11 , buildBenchmarks ? false
  12 , gpuTargets ? [ ]
  13 }:
  14
  15 stdenv.mkDerivation (finalAttrs: {
  16   pname = "rocprim";
  17   version = "5.7.1";
  18
  19   outputs = [
  20     "out"
  21   ] ++ lib.optionals buildTests [
  22     "test"
  23   ] ++ lib.optionals buildBenchmarks [
  24     "benchmark"
  25   ];
  26
  27   src = fetchFromGitHub {
  28     owner = "ROCm";
  29     repo = "rocPRIM";
  30     rev = "rocm-${finalAttrs.version}";
  31     hash = "sha256-+ukFWsWv3RhS+Z6tmR4TRT8QTYEDuAEk12F9Gv1eXGU=";
  32   };
  33
  34   nativeBuildInputs = [
  35     cmake
  36     rocm-cmake
  37     clr
  38   ];
  39
  40   buildInputs = lib.optionals buildTests [
  41     gtest
  42   ] ++ lib.optionals buildBenchmarks [
  43     gbenchmark
  44   ];
  45
  46   cmakeFlags = [
  47     "-DCMAKE_CXX_COMPILER=hipcc"
  48     # Manually define CMAKE_INSTALL_<DIR>
  49     # See: https://github.com/NixOS/nixpkgs/pull/197838
  50     "-DCMAKE_INSTALL_BINDIR=bin"
  51     "-DCMAKE_INSTALL_LIBDIR=lib"
  52     "-DCMAKE_INSTALL_INCLUDEDIR=include"
  53   ] ++ lib.optionals (gpuTargets != [ ]) [
  54     "-DAMDGPU_TARGETS=${lib.concatStringsSep ";" gpuTargets}"
  55   ] ++ lib.optionals buildTests [
  56     "-DBUILD_TEST=ON"
  57   ] ++ lib.optionals buildBenchmarks [
  58     "-DBUILD_BENCHMARK=ON"
  59   ];
  60
  61   postInstall = lib.optionalString buildTests ''
  62     mkdir -p $test/bin
  63     mv $out/bin/test_* $test/bin
  64     mv $out/bin/rocprim $test/bin
  65   '' + lib.optionalString buildBenchmarks ''
  66     mkdir -p $benchmark/bin
  67     mv $out/bin/benchmark_* $benchmark/bin
  68   '' + lib.optionalString (buildTests || buildBenchmarks) ''
  69     rmdir $out/bin
  70   '';
  71
  72   passthru.updateScript = rocmUpdateScript {
  73     name = finalAttrs.pname;
  74     owner = finalAttrs.src.owner;
  75     repo = finalAttrs.src.repo;
  76   };
  77
  78   meta = with lib; {
  79     description = "ROCm parallel primitives";
  80     homepage = "https://github.com/ROCm/rocPRIM";
  81     license = with licenses; [ mit ];
  82     maintainers = teams.rocm.members;
  83     platforms = platforms.linux;
  84     broken = versions.minor finalAttrs.version != versions.minor stdenv.cc.version || versionAtLeast finalAttrs.version "6.0.0";
  85   };
  86 })