pkgs/by-name/an/antora/test/default.nix

   1 {
   2   antora,
   3   antora-lunr-extension,
   4   antora-lunr-extension-test ? false,
   5   antora-ui-default,
   6   gitMinimal,
   7   lib,
   8   stdenvNoCC,
   9 }:
  10 stdenvNoCC.mkDerivation {
  11   name = "${antora.pname}${lib.optionalString antora-lunr-extension-test "-${antora-lunr-extension.pname}"}-test";
  12   src = ./minimal_working_example;
  13
  14   postPatch =
  15     let
  16       date = lib.escapeShellArg "1/1/1970 00:00:00 +0000";
  17     in
  18     ''
  19       # > In order to use a local content repository with Antora, even when using
  20       # > the worktree (HEAD), the repository must have at least one commit.
  21       # >
  22       # > -- https://docs.antora.org/antora/3.1/playbook/content-source-url
  23       git init &&
  24         GIT_AUTHOR_DATE=${date} \
  25         GIT_AUTHOR_EMAIL= \
  26         GIT_AUTHOR_NAME=Nixpkgs \
  27         GIT_COMMITTER_DATE=${date} \
  28         GIT_COMMITTER_EMAIL= \
  29         GIT_COMMITTER_NAME=Nixpkgs \
  30         git commit --allow-empty --allow-empty-message --message ""
  31     '';
  32
  33   buildPhase =
  34     let
  35       playbook = builtins.toFile "antora-playbook.json" (
  36         builtins.toJSON {
  37           content.sources = [ { url = "~+"; } ];
  38           runtime.log.failure_level = "warn";
  39         }
  40       );
  41     in
  42     ''
  43       # The --to-dir and --ui-bundle-url options are not included in the
  44       # playbook due to Antora and Nix limitations.
  45       antora ${
  46         lib.cli.toGNUCommandLineShell { } {
  47           cache-dir = "$(mktemp --directory)";
  48           extension = if antora-lunr-extension-test then antora-lunr-extension else false;
  49           to-dir = placeholder "out";
  50           ui-bundle-url = "${antora-ui-default}/ui-bundle.zip";
  51         }
  52       } "${playbook}"
  53     '';
  54
  55   nativeBuildInputs = [
  56     antora
  57     gitMinimal
  58   ];
  59
  60   meta = {
  61     description = "Reproducible Antora test framework";
  62     license = lib.licenses.mit;
  63     maintainers = [ lib.maintainers.naho ];
  64     platforms = lib.platforms.all;
  65   };
  66 }