pkgs/by-name/au/autotools-language-server/package.nix

   1 { lib
   2 , python311
   3 , fetchFromGitHub
   4 , fetchpatch
   5 }:
   6
   7 let
   8   python3 = python311.override {
   9     self = python3;
  10     packageOverrides = _: super: {
  11       tree-sitter = super.tree-sitter_0_21;
  12       lsp-tree-sitter = super.lsp-tree-sitter.overridePythonAttrs(__: {
  13         pythonRelaxDeps = [ "tree-sitter" ];
  14       });
  15     };
  16   };
  17 in
  18 python3.pkgs.buildPythonApplication rec {
  19   pname = "autotools-language-server";
  20   version = "0.0.19";
  21   pyproject = true;
  22
  23   src = fetchFromGitHub {
  24     owner = "Freed-Wu";
  25     repo = "autotools-language-server";
  26     rev = "refs/tags/${version}";
  27     hash = "sha256-V0EOV1ZmeC+4svc2fqV6AIiL37dkrxUJAnjywMZcENw=";
  28   };
  29   patches = [
  30     # Right before the release, upstream decided to replace the
  31     # tree-sitter-languages dependency with tree-sitter-make, which is yanked
  32     # from some reason. Hopefully upstream will fix this dependency a bit
  33     # better in the next release. See also:
  34     # https://github.com/Freed-Wu/autotools-language-server/commit/f149843becfcfd6b2bb4a98eb1f3984c01d5fd33#r142659163
  35     (fetchpatch {
  36       url = "https://github.com/Freed-Wu/autotools-language-server/commit/f149843becfcfd6b2bb4a98eb1f3984c01d5fd33.patch";
  37       hash = "sha256-TrzHbfR6GYAEqDIFiCqSX2+Qv4JeFJ5faiKJhNYojf0=";
  38       revert = true;
  39     })
  40   ];
  41
  42   build-system = [
  43     python3.pkgs.setuptools-generate
  44     python3.pkgs.setuptools-scm
  45   ];
  46
  47   dependencies = with python3.pkgs; [
  48     tree-sitter-languages
  49     lsp-tree-sitter
  50   ];
  51   nativeCheckInputs = [
  52     python3.pkgs.pytestCheckHook
  53   ];
  54
  55   meta = with lib; {
  56     description = "Autotools language server, support configure.ac, Makefile.am, Makefile";
  57     homepage = "https://github.com/Freed-Wu/autotools-language-server";
  58     license = licenses.gpl3Only;
  59     maintainers = with maintainers; [ doronbehar ];
  60     mainProgram = "autotools-language-server";
  61   };
  62 }