pkgs/by-name/ca/caffeine-ng/package.nix

   1 { fetchFromGitea
   2 , meson
   3 , ninja
   4 , pkg-config
   5 , scdoc
   6 , gobject-introspection
   7 , lib
   8 , libayatana-appindicator
   9 , libnotify
  10 , python3Packages
  11 , procps
  12 , xset
  13 , xautolock
  14 , xscreensaver
  15 , xfce
  16 , wrapGAppsHook3
  17 }:
  18
  19 python3Packages.buildPythonApplication rec {
  20   pname = "caffeine-ng";
  21   version = "4.2.0";
  22   format = "other";
  23
  24   src = fetchFromGitea {
  25     domain = "codeberg.org";
  26     owner = "WhyNotHugo";
  27     repo = pname;
  28     rev = "v${version}";
  29     hash = "sha256-uYzLRZ+6ZgIwhSuJWRBpLYHgonX7sFXgUZid0V26V0Q=";
  30   };
  31
  32   nativeBuildInputs = [ gobject-introspection meson ninja pkg-config wrapGAppsHook3 ];
  33
  34   buildInputs = [
  35     libayatana-appindicator
  36     libnotify
  37   ];
  38
  39   pythonPath = with python3Packages; [
  40     click
  41     dbus-python
  42     ewmh
  43     pulsectl
  44     pygobject3
  45     scdoc
  46     setproctitle
  47   ];
  48
  49   dontWrapGApps = true;
  50
  51   patches = [
  52     ./fix-build.patch
  53   ];
  54
  55   postPatch = ''
  56     echo "${version}" > version
  57   '';
  58
  59   postInstall = ''
  60     glib-compile-schemas $out/share/glib-2.0/schemas
  61   '';
  62
  63   preFixup = ''
  64     gappsWrapperArgs+=(
  65       --prefix PATH : ${lib.makeBinPath [ procps xautolock xscreensaver xfce.xfconf xset ]}
  66     )
  67     makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  68   '';
  69
  70   meta = with lib; {
  71     mainProgram = "caffeine";
  72     maintainers = with maintainers; [ marzipankaiser ];
  73     description = "Status bar application to temporarily inhibit screensaver and sleep mode";
  74     homepage = "https://codeberg.org/WhyNotHugo/caffeine-ng";
  75     changelog = "https://codeberg.org/WhyNotHugo/caffeine-ng/src/tag/v${version}/CHANGELOG.rst";
  76     license = licenses.gpl3;
  77     platforms = platforms.linux;
  78   };
  79 }