pkgs/by-name/di/discord-sh/package.nix

   1 { lib, stdenvNoCC, fetchFromGitHub, makeWrapper, curl, jq, coreutils, file }:
   2
   3 stdenvNoCC.mkDerivation rec {
   4   pname = "discord-sh";
   5   version = "2.0.0";
   6
   7   src = fetchFromGitHub {
   8     owner = "ChaoticWeg";
   9     repo = "discord.sh";
  10     rev = "v${version}";
  11     sha256 = "sha256-ZOGhwR9xFzkm+q0Gm8mSXZ9toXG4xGPNwBQMCVanCbY=";
  12   };
  13
  14   # ignore Makefile by disabling buildPhase. Upstream Makefile tries to download
  15   # binaries from the internet for linting
  16   dontBuild = true;
  17
  18   # discord.sh looks for the .webhook file in the source code directory, which
  19   # isn't mutable on Nix
  20   postPatch = ''
  21     substituteInPlace discord.sh \
  22       --replace 'thisdir="$(cd "$(dirname "$(readlink -f "''${BASH_SOURCE[0]}")")" && pwd)"' 'thisdir="$(pwd)"'
  23   '';
  24
  25   nativeBuildInputs = [ makeWrapper ];
  26
  27   doInstallCheck = true;
  28
  29   installCheckPhase = ''
  30     runHook preCheck
  31     $out/bin/discord.sh --help
  32     runHook postCheck
  33   '';
  34
  35   installPhase = ''
  36     runHook preInstall
  37     install -Dm555 discord.sh $out/bin/discord.sh
  38     wrapProgram $out/bin/discord.sh \
  39       --set PATH "${lib.makeBinPath [ curl jq coreutils file ]}"
  40     runHook postInstall
  41   '';
  42
  43   meta = with lib; {
  44     description = "Write-only command-line Discord webhook integration written in 100% Bash script";
  45     mainProgram = "discord.sh";
  46     homepage = "https://github.com/ChaoticWeg/discord.sh";
  47     license = licenses.gpl3;
  48     platforms = platforms.unix;
  49     maintainers = with maintainers; [ matthewcroughan ];
  50   };
  51 }