pkgs/tools/networking/bukubrow/default.nix

   1 { lib, rustPlatform, fetchFromGitHub, sqlite }: let
   2
   3 manifest = {
   4   description = "Bukubrow extension host application";
   5   name = "com.samhh.bukubrow";
   6   path = "@out@/bin/bukubrow";
   7   type = "stdio";
   8 };
   9
  10 in rustPlatform.buildRustPackage rec {
  11   pname = "bukubrow-host";
  12   version = "5.0.0";
  13
  14   src = fetchFromGitHub {
  15     owner = "SamHH";
  16     repo = pname;
  17     rev = "v${version}";
  18     sha256 = "1a3gqxj6d1shv3w0v9m8x2xr0bvcynchy778yqalxkc3x4vr0nbn";
  19   };
  20
  21   cargoSha256 = "1k6mffcs9g0z5lh8hpflyharx6653cs1f2rjpldab0fc5fjmjfza";
  22
  23   buildInputs = [ sqlite ];
  24
  25   passAsFile = [ "firefoxManifest" "chromeManifest" ];
  26   firefoxManifest = builtins.toJSON (manifest // {
  27     allowed_extensions = [ "bukubrow@samhh.com" ];
  28   });
  29   chromeManifest = builtins.toJSON (manifest // {
  30     allowed_origins = [ "chrome-extension://ghniladkapjacfajiooekgkfopkjblpn/" ];
  31   });
  32   postBuild = ''
  33     substituteAll $firefoxManifestPath firefox.json
  34     substituteAll $chromeManifestPath chrome.json
  35   '';
  36   postInstall = ''
  37     install -Dm0644 firefox.json $out/lib/mozilla/native-messaging-hosts/com.samhh.bukubrow.json
  38     install -Dm0644 chrome.json $out/etc/chromium/native-messaging-hosts/com.samhh.bukubrow.json
  39   '';
  40
  41   meta = with lib; {
  42     description = "A WebExtension for Buku, a command-line bookmark manager";
  43     homepage = "https://github.com/SamHH/bukubrow-host";
  44     license = licenses.gpl3;
  45     maintainers = with maintainers; [ infinisil ];
  46   };
  47 }
  48