pkgs/os-specific/linux/rtl8821au/default.nix

   1 { lib, stdenv, fetchFromGitHub, kernel, bc, nukeReferences }:
   2
   3 stdenv.mkDerivation {
   4   pname = "rtl8821au";
   5   version = "${kernel.version}-unstable-2024-03-16";
   6
   7   src = fetchFromGitHub {
   8     owner = "morrownr";
   9     repo = "8821au-20210708";
  10     rev = "168ac48174067e17ffb9f8b15ab802f37447dacc";
  11     hash = "sha256-eB9RCoU5jg5fgZkfcef9fsQ6tyD8gTPD+wYcR6PbWNw=";
  12   };
  13
  14   nativeBuildInputs = [ bc nukeReferences ] ++ kernel.moduleBuildDependencies;
  15
  16   hardeningDisable = [ "pic" "format" ];
  17
  18   env.NIX_CFLAGS_COMPILE = "-Wno-error=incompatible-pointer-types";
  19
  20   makeFlags = [
  21     "ARCH=${stdenv.hostPlatform.linuxArch}"
  22     ("CONFIG_PLATFORM_I386_PC=" + (if stdenv.hostPlatform.isx86 then "y" else "n"))
  23     ("CONFIG_PLATFORM_ARM_RPI=" + (if (stdenv.hostPlatform.isAarch32 || stdenv.hostPlatform.isAarch64) then "y" else "n"))
  24   ] ++ lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
  25     "CROSS_COMPILE=${stdenv.cc.targetPrefix}"
  26   ];
  27
  28   prePatch = ''
  29     substituteInPlace ./Makefile \
  30       --replace /lib/modules/ "${kernel.dev}/lib/modules/" \
  31       --replace /sbin/depmod \# \
  32       --replace '$(MODDESTDIR)' "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
  33   '';
  34
  35   preInstall = ''
  36     mkdir -p "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
  37   '';
  38
  39   postInstall = ''
  40     nuke-refs $out/lib/modules/*/kernel/net/wireless/*.ko
  41   '';
  42
  43   enableParallelBuilding = true;
  44
  45   meta = with lib; {
  46     description = "rtl8821AU and rtl8812AU chipset driver with firmware";
  47     homepage = "https://github.com/morrownr/8821au";
  48     license = licenses.gpl2Only;
  49     platforms = lib.platforms.linux;
  50     maintainers = with maintainers; [ plchldr ];
  51   };
  52 }