pkgs/development/interpreters/gauche/boot.nix

   1 {
   2   stdenv,
   3   lib,
   4   fetchurl,
   5   pkg-config,
   6   texinfo,
   7   libiconv,
   8   gdbm,
   9   openssl,
  10   zlib,
  11   mbedtls,
  12   cacert,
  13   darwin,
  14 }:
  15
  16 stdenv.mkDerivation rec {
  17   pname = "gauche-bootstrap";
  18   version = "0.9.15";
  19
  20   src = fetchurl {
  21     url = "https://github.com/shirok/Gauche/releases/download/release${
  22       lib.replaceStrings [ "." ] [ "_" ] version
  23     }/Gauche-${version}.tgz";
  24     hash = "sha256-NkPie8fIgiz9b7KJLbGF9ljo42STi8LM/O2yOeNa94M=";
  25   };
  26
  27   nativeBuildInputs = [
  28     pkg-config
  29     texinfo
  30   ];
  31
  32   buildInputs =
  33     [
  34       libiconv
  35       gdbm
  36       openssl
  37       zlib
  38       mbedtls
  39       cacert
  40     ]
  41     ++ lib.optionals (stdenv.isDarwin) [
  42       darwin.apple_sdk_11_0.frameworks.CoreServices
  43     ];
  44
  45   postPatch = ''
  46     patchShebangs .
  47   '';
  48
  49   configureFlags = [
  50     "--with-iconv=${libiconv}"
  51     "--with-dbm=gdbm"
  52     "--with-zlib=${zlib}"
  53     "--with-ca-bundle=${cacert}/etc/ssl/certs/ca-bundle.crt"
  54     # TODO: Enable slib
  55     #       Current slib in nixpkgs is specialized to Guile
  56     # "--with-slib=${slibGuile}/lib/slib"
  57   ];
  58
  59   enableParallelBuilding = true;
  60
  61   # TODO: Fix tests that fail in sandbox build
  62   doCheck = false;
  63
  64   meta = with lib; {
  65     description = "R7RS Scheme scripting engine (released version)";
  66     homepage = "https://practical-scheme.net/gauche/";
  67     mainProgram = "gosh";
  68     maintainers = with maintainers; [ mnacamura ];
  69     license = licenses.bsd3;
  70     platforms = platforms.unix;
  71   };
  72 }