pkgs/servers/mautrix-telegram/default.nix

   1 { lib
   2 , python3
   3 , fetchPypi
   4 , fetchFromGitHub
   5 , withE2BE ? true
   6 }:
   7
   8 let
   9   python = python3.override {
  10     self = python;
  11     packageOverrides = self: super: {
  12       tulir-telethon = self.telethon.overridePythonAttrs (oldAttrs: rec {
  13         version = "1.37.0a1";
  14         pname = "tulir-telethon";
  15         src = fetchPypi {
  16           inherit pname version;
  17           hash = "sha256-FckMHqGaBsqvFbrEnDWqJAQG8j/euY2NooesnxV6Kcc=";
  18         };
  19         doCheck = false;
  20       });
  21     };
  22   };
  23 in
  24 python.pkgs.buildPythonPackage rec {
  25   pname = "mautrix-telegram";
  26   version = "0.15.2";
  27   disabled = python.pythonOlder "3.8";
  28
  29   src = fetchFromGitHub {
  30     owner = "mautrix";
  31     repo = "telegram";
  32     rev = "refs/tags/v${version}";
  33     hash = "sha256-uR0vhp7ONyjwMKbgM1iObpFRoQzyQzJLbw4i9P58jTs=";
  34   };
  35
  36   format = "setuptools";
  37
  38   patches = [ ./0001-Re-add-entrypoint.patch ];
  39
  40   propagatedBuildInputs = with python.pkgs; ([
  41     ruamel-yaml
  42     python-magic
  43     commonmark
  44     aiohttp
  45     yarl
  46     (mautrix.override { withOlm = withE2BE; })
  47     tulir-telethon
  48     asyncpg
  49     mako
  50     setuptools
  51     # speedups
  52     cryptg
  53     aiodns
  54     brotli
  55     # qr_login
  56     pillow
  57     qrcode
  58     # formattednumbers
  59     phonenumbers
  60     # metrics
  61     prometheus-client
  62     # sqlite
  63     aiosqlite
  64     # proxy support
  65     pysocks
  66   ] ++ lib.optionals withE2BE [
  67     # e2be
  68     python-olm
  69     pycryptodome
  70     unpaddedbase64
  71   ]);
  72
  73   # has no tests
  74   doCheck = false;
  75
  76   meta = with lib; {
  77     homepage = "https://github.com/mautrix/telegram";
  78     description = "Matrix-Telegram hybrid puppeting/relaybot bridge";
  79     license = licenses.agpl3Plus;
  80     platforms = platforms.linux;
  81     maintainers = with maintainers; [ nyanloutre ma27 nickcao ];
  82     mainProgram = "mautrix-telegram";
  83   };
  84 }