flake.nix

   1 # Experimental flake interface to Nixpkgs.
   2 # See https://github.com/NixOS/rfcs/pull/49 for details.
   3 {
   4   description = "A collection of packages for the Nix package manager";
   5
   6   outputs = { self }:
   7     let
   8       jobs = import ./pkgs/top-level/release.nix {
   9         nixpkgs = self;
  10       };
  11
  12       lib = import ./lib;
  13
  14       forAllSystems = f: lib.genAttrs lib.systems.flakeExposed (system: f system);
  15
  16     in
  17     {
  18       lib = lib.extend (final: prev: {
  19
  20         nixos = import ./nixos/lib { lib = final; };
  21
  22         nixosSystem = args:
  23           import ./nixos/lib/eval-config.nix (
  24             args // {
  25               modules = args.modules ++ [{
  26                 system.nixos.versionSuffix =
  27                   ".${final.substring 0 8 (self.lastModifiedDate or self.lastModified or "19700101")}.${self.shortRev or "dirty"}";
  28                 system.nixos.revision = final.mkIf (self ? rev) self.rev;
  29               }];
  30             } // lib.optionalAttrs (! args?system) {
  31               # Allow system to be set modularly in nixpkgs.system.
  32               # We set it to null, to remove the "legacy" entrypoint's
  33               # non-hermetic default.
  34               system = null;
  35             }
  36           );
  37       });
  38
  39       checks.x86_64-linux.tarball = jobs.tarball;
  40
  41       htmlDocs = {
  42         nixpkgsManual = jobs.manual;
  43         nixosManual = (import ./nixos/release-small.nix {
  44           nixpkgs = self;
  45         }).nixos.manual.x86_64-linux;
  46       };
  47
  48       # The "legacy" in `legacyPackages` doesn't imply that the packages exposed
  49       # through this attribute are "legacy" packages. Instead, `legacyPackages`
  50       # is used here as a substitute attribute name for `packages`. The problem
  51       # with `packages` is that it makes operations like `nix flake show
  52       # nixpkgs` unusably slow due to the sheer number of packages the Nix CLI
  53       # needs to evaluate. But when the Nix CLI sees a `legacyPackages`
  54       # attribute it displays `omitted` instead of evaluating all packages,
  55       # which keeps `nix flake show` on Nixpkgs reasonably fast, though less
  56       # information rich.
  57       legacyPackages = forAllSystems (system: import ./. { inherit system; });
  58
  59       nixosModules = {
  60         notDetected = import ./nixos/modules/installer/scan/not-detected.nix;
  61       };
  62     };
  63 }