doc/languages-frameworks/idris2.section.md

   1 # Idris2 {#sec-idris2}
   2
   3 In addition to exposing the Idris2 compiler itself, Nixpkgs exposes an `idris2Packages.buildIdris` helper to make it a bit more ergonomic to build Idris2 executables or libraries.
   4
   5 The `buildIdris` function takes an attribute set that defines at a minimum the `src` and `ipkgName` of the package to be built and any `idrisLibraries` required to build it. The `src` is the same source you're familiar with and the `ipkgName` must be the name of the `ipkg` file for the project (omitting the `.ipkg` extension). The `idrisLibraries` is a list of other library derivations created with `buildIdris`. You can optionally specify other derivation properties as needed but sensible defaults for `configurePhase`, `buildPhase`, and `installPhase` are provided.
   6
   7 Importantly, `buildIdris` does not create a single derivation but rather an attribute set with two properties: `executable` and `library`. The `executable` property is a derivation and the `library` property is a function that will return a derivation for the library with or without source code included. Source code need not be included unless you are aiming to use IDE or LSP features that are able to jump to definitions within an editor.
   8
   9 A simple example of a fully packaged library would be the [`LSP-lib`](https://github.com/idris-community/LSP-lib) found in the `idris-community` GitHub organization.
  10 ```nix
  11 { fetchFromGitHub, idris2Packages }:
  12 let lspLibPkg = idris2Packages.buildIdris {
  13   ipkgName = "lsp-lib";
  14   src = fetchFromGitHub {
  15    owner = "idris-community";
  16    repo = "LSP-lib";
  17    rev = "main";
  18    hash = "sha256-EvSyMCVyiy9jDZMkXQmtwwMoLaem1GsKVFqSGNNHHmY=";
  19   };
  20   idrisLibraries = [ ];
  21 };
  22 in lspLibPkg.library { withSource = true; }
  23 ```
  24
  25 The above results in a derivation with the installed library results (with sourcecode).
  26
  27 A slightly more involved example of a fully packaged executable would be the [`idris2-lsp`](https://github.com/idris-community/idris2-lsp) which is an Idris2 language server that uses the `LSP-lib` found above.
  28 ```nix
  29 { callPackage, fetchFromGitHub, idris2Packages }:
  30
  31 # Assuming the previous example lives in `lsp-lib.nix`:
  32 let lspLib = callPackage ./lsp-lib.nix { };
  33     inherit (idris2Packages) idris2Api;
  34     lspPkg = idris2Packages.buildIdris {
  35       ipkgName = "idris2-lsp";
  36       src = fetchFromGitHub {
  37          owner = "idris-community";
  38          repo = "idris2-lsp";
  39          rev = "main";
  40          hash = "sha256-vQTzEltkx7uelDtXOHc6QRWZ4cSlhhm5ziOqWA+aujk=";
  41       };
  42       idrisLibraries = [idris2Api lspLib];
  43     };
  44 in lspPkg.executable
  45 ```
  46
  47 The above uses the default value of `withSource = false` for the `idris2Api` but could be modified to include that library's source by passing `(idris2Api { withSource = true; })` to `idrisLibraries` instead. `idris2Api` in the above derivation comes built in with `idris2Packages`. This library exposes many of the otherwise internal APIs of the Idris2 compiler.