pkgs/servers/matrix-synapse/wrapper.nix

   1 { lib
   2 , stdenv
   3 , makeWrapper
   4 , matrix-synapse-unwrapped
   5 , extras ? [
   6     "postgres"
   7     "url-preview"
   8     "user-search"
   9   ] ++ lib.optional (lib.meta.availableOn stdenv.hostPlatform matrix-synapse-unwrapped.python.pkgs.systemd) "systemd"
  10 , plugins ? [ ]
  11 , ...
  12 }:
  13
  14 let
  15   extraPackages = lib.concatMap (extra: matrix-synapse-unwrapped.optional-dependencies.${extra}) (lib.unique extras);
  16
  17   pythonEnv = matrix-synapse-unwrapped.python.buildEnv.override {
  18     extraLibs = extraPackages ++ plugins;
  19   };
  20
  21   searchPath = "${pythonEnv}/${matrix-synapse-unwrapped.python.sitePackages}";
  22 in
  23 stdenv.mkDerivation {
  24   name = (lib.appendToName "wrapped" matrix-synapse-unwrapped).name;
  25
  26   nativeBuildInputs = [
  27     makeWrapper
  28   ];
  29
  30   buildCommand = ''
  31     for bin in ${matrix-synapse-unwrapped}/bin/*; do
  32       echo $bin
  33       makeWrapper "$bin" "$out/bin/$(basename $bin)" \
  34         --set PYTHONPATH ${searchPath}
  35     done;
  36   '';
  37
  38   passthru = {
  39     unwrapped = matrix-synapse-unwrapped;
  40
  41     # for backward compatibility
  42     inherit (matrix-synapse-unwrapped) plugins tests tools;
  43   };
  44
  45   # Carry the maintainer, licenses, and various useful information.
  46   inherit (matrix-synapse-unwrapped) meta;
  47 }