pkgs/servers/polaris/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitHub
   4 , rustPlatform
   5 , nix-update-script
   6 , polaris-web
   7 , darwin
   8 , nixosTests
   9 }:
  10
  11 rustPlatform.buildRustPackage rec {
  12   pname = "polaris";
  13   version = "0.14.3";
  14
  15   src = fetchFromGitHub {
  16     owner = "agersant";
  17     repo = "polaris";
  18     rev = version;
  19     hash = "sha256-2GHYIlEzRS7KXahdrxMjyIcPCNw8gXJw5/4ZpB/zT3Y=";
  20
  21     # The polaris version upstream in Cargo.lock is "0.0.0".
  22     # We're unable to simply patch it in the patch phase due to
  23     # rustPlatform.buildRustPackage fetching dependencies before applying patches.
  24     # If we patch it after fetching dependencies we get an error when
  25     # validating consistency between the final build and the prefetched deps.
  26     postFetch = ''
  27       # 'substituteInPlace' does not support multiline replacements?
  28       sed -i $out/Cargo.lock -z \
  29         -e 's/\[\[package\]\]\nname = "polaris"\nversion = "0.0.0"/[[package]]\nname = "polaris"\nversion = "'"${version}"'"/g'
  30     '';
  31   };
  32
  33   cargoHash = if stdenv.buildPlatform.isDarwin
  34     then "sha256-HTqsghjfSjwOaN/ApPFvWVEoquZzE3MYzULkhUOXIWI"
  35     else "sha256-Z3AbYtdNAyKT5EuGtCktEg0fxs/gpKdsrttRkxZhLAU";
  36
  37   buildInputs = lib.optionals stdenv.hostPlatform.isDarwin [
  38     darwin.Security
  39   ];
  40
  41   # Compile-time environment variables for where to find assets needed at runtime
  42   env = {
  43     POLARIS_WEB_DIR = "${polaris-web}/share/polaris-web";
  44     POLARIS_SWAGGER_DIR = "${placeholder "out"}/share/polaris-swagger";
  45   };
  46
  47   postInstall = ''
  48     mkdir -p $out/share
  49     cp -a docs/swagger $out/share/polaris-swagger
  50   '';
  51
  52   preCheck = ''
  53     # 'Err' value: Os { code: 24, kind: Uncategorized, message: "Too many open files" }
  54     ulimit -n 4096
  55   '';
  56
  57   __darwinAllowLocalNetworking = true;
  58
  59   passthru.tests = nixosTests.polaris;
  60   passthru.updateScript = nix-update-script { };
  61
  62   meta = with lib; {
  63     description = "Self-host your music collection, and access it from any computer and mobile device";
  64     longDescription = ''
  65       Polaris is a FOSS music streaming application, designed to let you enjoy your music collection
  66       from any computer or mobile device. Polaris works by streaming your music directly from your
  67       own computer, without uploading it to a third-party. There are no  kind of premium version.
  68       The only requirement is that your computer stays on while it streams your music!
  69     '';
  70     homepage = "https://github.com/agersant/polaris";
  71     license = licenses.mit;
  72     maintainers = with maintainers; [ pbsds ];
  73     platforms = platforms.unix;
  74     mainProgram = "polaris";
  75   };
  76 }