nixos/modules/i18n/input-method/default.nix

   1 { config, pkgs, lib, ... }:
   2 let
   3   cfg = config.i18n.inputMethod;
   4
   5   allowedTypes = lib.types.enum [ "ibus" "fcitx5" "nabi" "uim" "hime" "kime" ];
   6
   7   gtk2_cache = pkgs.runCommand "gtk2-immodule.cache"
   8     { preferLocalBuild = true;
   9       allowSubstitutes = false;
  10       buildInputs = [ pkgs.gtk2 cfg.package ];
  11     }
  12     ''
  13       mkdir -p $out/etc/gtk-2.0/
  14       GTK_PATH=${cfg.package}/lib/gtk-2.0/ gtk-query-immodules-2.0 > $out/etc/gtk-2.0/immodules.cache
  15     '';
  16
  17   gtk3_cache = pkgs.runCommand "gtk3-immodule.cache"
  18     { preferLocalBuild = true;
  19       allowSubstitutes = false;
  20       buildInputs = [ pkgs.gtk3 cfg.package ];
  21     }
  22     ''
  23       mkdir -p $out/etc/gtk-3.0/
  24       GTK_PATH=${cfg.package}/lib/gtk-3.0/ gtk-query-immodules-3.0 > $out/etc/gtk-3.0/immodules.cache
  25     '';
  26
  27 in
  28 {
  29   options.i18n = {
  30     inputMethod = {
  31       enable = lib.mkEnableOption "an additional input method type" // {
  32         default = cfg.enabled != null;
  33         defaultText = lib.literalMD "`true` if the deprecated option `enabled` is set, false otherwise";
  34       };
  35
  36       enabled = lib.mkOption {
  37         type    = lib.types.nullOr allowedTypes;
  38         default = null;
  39         example = "fcitx5";
  40         description = "Deprecated - use `type` and `enable = true` instead";
  41       };
  42
  43       type = lib.mkOption {
  44         type    = lib.types.nullOr allowedTypes;
  45         default = cfg.enabled;
  46         defaultText = lib.literalMD "The value of the deprecated option `enabled`, defaulting to null";
  47         example = "fcitx5";
  48         description = ''
  49           Select the enabled input method. Input methods is a software to input symbols that are not available on standard input devices.
  50
  51           Input methods are specially used to input Chinese, Japanese and Korean characters.
  52
  53           Currently the following input methods are available in NixOS:
  54
  55           - ibus: The intelligent input bus, extra input engines can be added using `i18n.inputMethod.ibus.engines`.
  56           - fcitx5: The next generation of fcitx, addons (including engines, dictionaries, skins) can be added using `i18n.inputMethod.fcitx5.addons`.
  57           - nabi: A Korean input method based on XIM. Nabi doesn't support Qt 5.
  58           - uim: The universal input method, is a library with a XIM bridge. uim mainly support Chinese, Japanese and Korean.
  59           - hime: An extremely easy-to-use input method framework.
  60           - kime: Koream IME.
  61         '';
  62       };
  63
  64       package = lib.mkOption {
  65         internal = true;
  66         type     = lib.types.nullOr lib.types.path;
  67         default  = null;
  68         description = ''
  69           The input method method package.
  70         '';
  71       };
  72     };
  73   };
  74
  75   config = lib.mkIf cfg.enable {
  76     warnings = lib.optional (cfg.enabled != null) "i18n.inputMethod.enabled will be removed in a future release. Please use .type, and .enable = true instead";
  77     environment.systemPackages = [ cfg.package gtk2_cache gtk3_cache ];
  78   };
  79
  80   meta = {
  81     maintainers = with lib.maintainers; [ ericsagnes ];
  82     doc = ./default.md;
  83   };
  84
  85 }