pkgs/development/interpreters/erlang/generic-builder.nix

   1 { pkgs
   2 , lib
   3 , stdenv
   4 , fetchFromGitHub
   5 , makeWrapper
   6 , gawk
   7 , gnum4
   8 , gnused
   9 , libxml2
  10 , libxslt
  11 , ncurses
  12 , openssl
  13 , perl
  14 , autoconf
  15 , openjdk11 ? null # javacSupport
  16 , unixODBC ? null # odbcSupport
  17 , libGL ? null
  18 , libGLU ? null
  19 , wxGTK ? null
  20 , wxmac ? null
  21 , xorg ? null
  22 , parallelBuild ? false
  23 , systemd
  24 , wxSupport ? true
  25 , systemdSupport ? stdenv.isLinux # systemd support in epmd
  26   # updateScript deps
  27 , writeScript
  28 , common-updater-scripts
  29 , coreutils
  30 , git
  31 }:
  32 { baseName ? "erlang"
  33 , version
  34 , sha256 ? null
  35 , rev ? "OTP-${version}"
  36 , src ? fetchFromGitHub { inherit rev sha256; owner = "erlang"; repo = "otp"; }
  37 , enableHipe ? true
  38 , enableDebugInfo ? false
  39 , enableThreads ? true
  40 , enableSmpSupport ? true
  41 , enableKernelPoll ? true
  42 , javacSupport ? false
  43 , javacPackages ? [ openjdk11 ]
  44 , odbcSupport ? false
  45 , odbcPackages ? [ unixODBC ]
  46 , opensslPackage ? openssl
  47 , wxPackages ? [ libGL libGLU wxGTK xorg.libX11 ]
  48 , preUnpack ? ""
  49 , postUnpack ? ""
  50 , patches ? [ ]
  51 , patchPhase ? ""
  52 , prePatch ? ""
  53 , postPatch ? ""
  54 , configureFlags ? [ ]
  55 , configurePhase ? ""
  56 , preConfigure ? ""
  57 , postConfigure ? ""
  58 , buildPhase ? ""
  59 , preBuild ? ""
  60 , postBuild ? ""
  61 , installPhase ? ""
  62 , preInstall ? ""
  63 , postInstall ? ""
  64 , installTargets ? [ "install" "install-docs" ]
  65 , checkPhase ? ""
  66 , preCheck ? ""
  67 , postCheck ? ""
  68 , fixupPhase ? ""
  69 , preFixup ? ""
  70 , postFixup ? ""
  71 , meta ? { }
  72 }:
  73
  74 assert wxSupport -> (if stdenv.isDarwin
  75 then wxmac != null
  76 else libGL != null && libGLU != null && wxGTK != null && xorg != null);
  77
  78 assert odbcSupport -> unixODBC != null;
  79 assert javacSupport -> openjdk11 != null;
  80
  81 let
  82   inherit (lib) optional optionals optionalAttrs optionalString;
  83   wxPackages2 = if stdenv.isDarwin then [ wxmac ] else wxPackages;
  84
  85 in
  86 stdenv.mkDerivation ({
  87   # name is used instead of pname to
  88   # - not have to pass pnames as argument
  89   # - have a separate pname for erlang (main module)
  90   name = "${baseName}"
  91     + optionalString javacSupport "_javac"
  92     + optionalString odbcSupport "_odbc"
  93     + "-${version}";
  94
  95   inherit src version;
  96
  97   nativeBuildInputs = [ autoconf makeWrapper perl gnum4 libxslt libxml2 ];
  98
  99   buildInputs = [ ncurses opensslPackage ]
 100     ++ optionals wxSupport wxPackages2
 101     ++ optionals odbcSupport odbcPackages
 102     ++ optionals javacSupport javacPackages
 103     ++ optional systemdSupport systemd
 104     ++ optionals stdenv.isDarwin (with pkgs.darwin.apple_sdk.frameworks; [ AGL Carbon Cocoa WebKit ]);
 105
 106   debugInfo = enableDebugInfo;
 107
 108   # On some machines, parallel build reliably crashes on `GEN    asn1ct_eval_ext.erl` step
 109   enableParallelBuilding = parallelBuild;
 110
 111   postPatch = ''
 112     patchShebangs make
 113
 114     ${postPatch}
 115   '';
 116
 117   preConfigure = ''
 118     ./otp_build autoconf
 119   '';
 120
 121   configureFlags = [ "--with-ssl=${lib.getOutput "out" opensslPackage}" ]
 122     ++ [ "--with-ssl-incl=${lib.getDev opensslPackage}" ] # This flag was introduced in R24
 123     ++ optional enableThreads "--enable-threads"
 124     ++ optional enableSmpSupport "--enable-smp-support"
 125     ++ optional enableKernelPoll "--enable-kernel-poll"
 126     ++ optional enableHipe "--enable-hipe"
 127     ++ optional javacSupport "--with-javac"
 128     ++ optional odbcSupport "--with-odbc=${unixODBC}"
 129     ++ optional wxSupport "--enable-wx"
 130     ++ optional systemdSupport "--enable-systemd"
 131     ++ optional stdenv.isDarwin "--enable-darwin-64bit"
 132     ++ configureFlags;
 133
 134   # install-docs will generate and install manpages and html docs
 135   # (PDFs are generated only when fop is available).
 136
 137   postInstall = ''
 138     ln -s $out/lib/erlang/lib/erl_interface*/bin/erl_call $out/bin/erl_call
 139
 140     ${postInstall}
 141   '';
 142
 143   # Some erlang bin/ scripts run sed and awk
 144   postFixup = ''
 145     wrapProgram $out/lib/erlang/bin/erl --prefix PATH ":" "${gnused}/bin/"
 146     wrapProgram $out/lib/erlang/bin/start_erl --prefix PATH ":" "${lib.makeBinPath [ gnused gawk ]}"
 147   '';
 148
 149   passthru = {
 150     updateScript =
 151       let major = builtins.head (builtins.splitVersion version);
 152       in
 153       writeScript "update.sh" ''
 154         #!${stdenv.shell}
 155         set -ox errexit
 156         PATH=${lib.makeBinPath [ common-updater-scripts coreutils git gnused ]}
 157         latest=$(list-git-tags --url=https://github.com/erlang/otp.git | sed -n 's/^OTP-${major}/${major}/p' | sort -V | tail -1)
 158         if [ "$latest" != "${version}" ]; then
 159           nixpkgs="$(git rev-parse --show-toplevel)"
 160           nix_file="$nixpkgs/pkgs/development/interpreters/erlang/R${major}.nix"
 161           update-source-version ${baseName}R${major} "$latest" --version-key=version --print-changes --file="$nix_file"
 162         else
 163           echo "${baseName}R${major} is already up-to-date"
 164         fi
 165       '';
 166   };
 167
 168   meta = with lib; ({
 169     homepage = "https://www.erlang.org/";
 170     downloadPage = "https://www.erlang.org/download.html";
 171     description = "Programming language used for massively scalable soft real-time systems";
 172
 173     longDescription = ''
 174       Erlang is a programming language used to build massively scalable
 175       soft real-time systems with requirements on high availability.
 176       Some of its uses are in telecoms, banking, e-commerce, computer
 177       telephony and instant messaging. Erlang's runtime system has
 178       built-in support for concurrency, distribution and fault
 179       tolerance.
 180     '';
 181
 182     platforms = platforms.unix;
 183     maintainers = teams.beam.members;
 184     license = licenses.asl20;
 185   } // meta);
 186 }
 187 // optionalAttrs (preUnpack != "") { inherit preUnpack; }
 188 // optionalAttrs (postUnpack != "") { inherit postUnpack; }
 189 // optionalAttrs (patches != [ ]) { inherit patches; }
 190 // optionalAttrs (prePatch != "") { inherit prePatch; }
 191 // optionalAttrs (patchPhase != "") { inherit patchPhase; }
 192 // optionalAttrs (configurePhase != "") { inherit configurePhase; }
 193 // optionalAttrs (preConfigure != "") { inherit preConfigure; }
 194 // optionalAttrs (postConfigure != "") { inherit postConfigure; }
 195 // optionalAttrs (buildPhase != "") { inherit buildPhase; }
 196 // optionalAttrs (preBuild != "") { inherit preBuild; }
 197 // optionalAttrs (postBuild != "") { inherit postBuild; }
 198 // optionalAttrs (checkPhase != "") { inherit checkPhase; }
 199 // optionalAttrs (preCheck != "") { inherit preCheck; }
 200 // optionalAttrs (postCheck != "") { inherit postCheck; }
 201 // optionalAttrs (installPhase != "") { inherit installPhase; }
 202 // optionalAttrs (installTargets != [ ]) { inherit installTargets; }
 203 // optionalAttrs (preInstall != "") { inherit preInstall; }
 204 // optionalAttrs (fixupPhase != "") { inherit fixupPhase; }
 205 // optionalAttrs (preFixup != "") { inherit preFixup; }
 206 // optionalAttrs (postFixup != "") { inherit postFixup; }
 207 )