pkgs/development/interpreters/evcxr/default.nix

   1 { cargo, fetchFromGitHub, makeWrapper, pkg-config, rustPlatform, lib, stdenv
   2 , gcc, cmake, libiconv, CoreServices, Security }:
   3
   4 rustPlatform.buildRustPackage rec {
   5   pname = "evcxr";
   6   version = "0.14.1";
   7
   8   src = fetchFromGitHub {
   9     owner = "google";
  10     repo = "evcxr";
  11     rev = "v${version}";
  12     sha256 = "sha256-sdvBAmINl/3Hv9gnPVruI5lCuSu1VQ9swY0GNJrsEVk=";
  13   };
  14
  15   cargoSha256 = "sha256-wKoseZTAZOeT0LEHTlnO5cMpYx6sinnQkEVXCYXupAY=";
  16
  17   RUST_SRC_PATH = "${rustPlatform.rustLibSrc}";
  18
  19   nativeBuildInputs = [ pkg-config makeWrapper cmake ];
  20   buildInputs = lib.optionals stdenv.isDarwin
  21     [ libiconv CoreServices Security ];
  22
  23   postInstall = let
  24     wrap = exe: ''
  25       wrapProgram $out/bin/${exe} \
  26         --prefix PATH : ${lib.makeBinPath [ cargo gcc ]} \
  27         --set-default RUST_SRC_PATH "$RUST_SRC_PATH"
  28     '';
  29   in ''
  30     ${wrap "evcxr"}
  31     ${wrap "evcxr_jupyter"}
  32     rm $out/bin/testing_runtime
  33   '';
  34
  35   meta = with lib; {
  36     description = "An evaluation context for Rust";
  37     homepage = "https://github.com/google/evcxr";
  38     license = licenses.asl20;
  39     maintainers = with maintainers; [ protoben ma27 ];
  40   };
  41 }