pkgs/development/libraries/geoclue/default.nix

   1 { lib
   2 , stdenv
   3 , fetchFromGitLab
   4 , fetchpatch
   5 , intltool
   6 , meson
   7 , mesonEmulatorHook
   8 , ninja
   9 , pkg-config
  10 , gtk-doc
  11 , docbook-xsl-nons
  12 , docbook_xml_dtd_412
  13 , glib
  14 , json-glib
  15 , libsoup
  16 , libnotify
  17 , gdk-pixbuf
  18 , modemmanager
  19 , avahi
  20 , glib-networking
  21 , python3
  22 , wrapGAppsHook
  23 , gobject-introspection
  24 , vala
  25 , withDemoAgent ? false
  26 }:
  27
  28 stdenv.mkDerivation rec {
  29   pname = "geoclue";
  30   version = "2.6.0";
  31
  32   outputs = [ "out" "dev" "devdoc" ];
  33
  34   src = fetchFromGitLab {
  35     domain = "gitlab.freedesktop.org";
  36     owner = "geoclue";
  37     repo = "geoclue";
  38     rev = version;
  39     hash = "sha256-TbuO9wpyjtvyvqaCryaTOunR0hVVlJuqENWQQpcMcz4=";
  40   };
  41
  42   patches = [
  43     ./add-option-for-installation-sysconfdir.patch
  44   ];
  45
  46   nativeBuildInputs = [
  47     pkg-config
  48     intltool
  49     meson
  50     ninja
  51     wrapGAppsHook
  52     python3
  53     vala
  54     gobject-introspection
  55     # devdoc
  56     gtk-doc
  57     docbook-xsl-nons
  58     docbook_xml_dtd_412
  59   ] ++ lib.optionals (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
  60     mesonEmulatorHook
  61   ];
  62
  63   buildInputs = [
  64     glib
  65     json-glib
  66     libsoup
  67     avahi
  68     gobject-introspection
  69   ] ++ lib.optionals withDemoAgent [
  70     libnotify gdk-pixbuf
  71   ] ++ lib.optionals (!stdenv.isDarwin) [
  72     modemmanager
  73   ];
  74
  75   propagatedBuildInputs = [
  76     glib
  77     glib-networking
  78   ];
  79
  80   mesonFlags = [
  81     "-Dsystemd-system-unit-dir=${placeholder "out"}/etc/systemd/system"
  82     "-Ddemo-agent=${lib.boolToString withDemoAgent}"
  83     "--sysconfdir=/etc"
  84     "-Dsysconfdir_install=${placeholder "out"}/etc"
  85     "-Dmozilla-api-key=5c28d1f4-9511-47ff-b11a-2bef80fc177c"
  86     "-Ddbus-srv-user=geoclue"
  87     "-Ddbus-sys-dir=${placeholder "out"}/share/dbus-1/system.d"
  88   ] ++ lib.optionals stdenv.isDarwin [
  89     "-D3g-source=false"
  90     "-Dcdma-source=false"
  91     "-Dmodem-gps-source=false"
  92     "-Dnmea-source=false"
  93   ];
  94
  95   postPatch = ''
  96     chmod +x demo/install-file.py
  97     patchShebangs demo/install-file.py
  98   '';
  99
 100   meta = with lib; {
 101     broken = stdenv.isDarwin && withDemoAgent;
 102     description = "Geolocation framework and some data providers";
 103     homepage = "https://gitlab.freedesktop.org/geoclue/geoclue/wikis/home";
 104     maintainers = with maintainers; [ raskin ];
 105     platforms = with platforms; linux ++ darwin;
 106     license = licenses.lgpl2Plus;
 107   };
 108 }