pkgs/development/libraries/librsvg/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , pkg-config
   5 , glib
   6 , gdk-pixbuf
   7 , pango
   8 , cairo
   9 , libxml2
  10 , bzip2
  11 , libintl
  12 , ApplicationServices
  13 , Foundation
  14 , libobjc
  15 , rustPlatform
  16 , rustc
  17 , rust
  18 , cargo
  19 , gi-docgen
  20 , python3Packages
  21 , gnome
  22 , vala
  23 , withIntrospection ? stdenv.hostPlatform == stdenv.buildPlatform
  24 , gobject-introspection
  25 , _experimental-update-script-combinators
  26 , common-updater-scripts
  27 , jq
  28 , nix
  29 }:
  30
  31 stdenv.mkDerivation rec {
  32   pname = "librsvg";
  33   version = "2.55.1";
  34
  35   outputs = [ "out" "dev" ] ++ lib.optionals withIntrospection [
  36     "devdoc"
  37   ];
  38
  39   src = fetchurl {
  40     url = "mirror://gnome/sources/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
  41     sha256 = "a69IqdOlb9E7v7ufH3Z1myQLcKH6Ig/SOEdNZqkm+Yw=";
  42   };
  43
  44   cargoDeps = rustPlatform.fetchCargoTarball {
  45     inherit src;
  46     name = "${pname}-${version}";
  47     hash = "sha256-nRmOB9Jo+mmB0+wXrQvoII4e0ucV7bNCDeuk6CbcPdk=";
  48     # TODO: move this to fetchCargoTarball
  49     dontConfigure = true;
  50   };
  51
  52   strictDeps = true;
  53
  54   depsBuildBuild = [ pkg-config ];
  55
  56   nativeBuildInputs = [
  57     gdk-pixbuf
  58     pkg-config
  59     rustc
  60     cargo
  61     python3Packages.docutils
  62     vala
  63     rustPlatform.cargoSetupHook
  64   ] ++ lib.optionals withIntrospection [
  65     gobject-introspection
  66     gi-docgen
  67   ];
  68
  69   buildInputs = [
  70     libxml2
  71     bzip2
  72     pango
  73     libintl
  74   ] ++ lib.optionals withIntrospection [
  75     gobject-introspection
  76   ] ++ lib.optionals stdenv.isDarwin [
  77     ApplicationServices
  78     Foundation
  79     libobjc
  80   ];
  81
  82   propagatedBuildInputs = [
  83     glib
  84     gdk-pixbuf
  85     cairo
  86   ];
  87
  88   configureFlags = [
  89     (lib.enableFeature withIntrospection "introspection")
  90
  91     # Vapi does not build on MacOS.
  92     # https://github.com/NixOS/nixpkgs/pull/117081#issuecomment-827782004
  93     (lib.enableFeature (withIntrospection && !stdenv.isDarwin) "vala")
  94
  95     "--enable-always-build-tests"
  96   ] ++ lib.optional stdenv.isDarwin "--disable-Bsymbolic"
  97     ++ lib.optional (stdenv.buildPlatform != stdenv.hostPlatform) "RUST_TARGET=${rust.toRustTarget stdenv.hostPlatform}";
  98
  99   doCheck = false; # all tests fail on libtool-generated rsvg-convert not being able to find coreutils
 100
 101   # It wants to add loaders and update the loaders.cache in gdk-pixbuf
 102   # Patching the Makefiles to it creates rsvg specific loaders and the
 103   # relevant loader.cache here.
 104   # The loaders.cache can be used by setting GDK_PIXBUF_MODULE_FILE to
 105   # point to this file in a wrapper.
 106   postConfigure = ''
 107     GDK_PIXBUF=$out/lib/gdk-pixbuf-2.0/2.10.0
 108     mkdir -p $GDK_PIXBUF/loaders
 109     sed -e "s#gdk_pixbuf_moduledir = .*#gdk_pixbuf_moduledir = $GDK_PIXBUF/loaders#" \
 110         -i gdk-pixbuf-loader/Makefile
 111     sed -e "s#gdk_pixbuf_cache_file = .*#gdk_pixbuf_cache_file = $GDK_PIXBUF/loaders.cache#" \
 112         -i gdk-pixbuf-loader/Makefile
 113     sed -e "s#\$(GDK_PIXBUF_QUERYLOADERS)#GDK_PIXBUF_MODULEDIR=$GDK_PIXBUF/loaders \$(GDK_PIXBUF_QUERYLOADERS)#" \
 114          -i gdk-pixbuf-loader/Makefile
 115
 116     # Fix thumbnailer path
 117     sed -e "s#@bindir@\(/gdk-pixbuf-thumbnailer\)#${gdk-pixbuf}/bin\1#g" \
 118         -i gdk-pixbuf-loader/librsvg.thumbnailer.in
 119
 120     # 'error: linker `cc` not found' when cross-compiling
 121     export RUSTFLAGS="-Clinker=$CC"
 122   '';
 123
 124   # Not generated when cross compiling.
 125   postInstall = lib.optionalString (stdenv.hostPlatform == stdenv.buildPlatform) ''
 126     # Merge gdkpixbuf and librsvg loaders
 127     cat ${lib.getLib gdk-pixbuf}/lib/gdk-pixbuf-2.0/2.10.0/loaders.cache $GDK_PIXBUF/loaders.cache > $GDK_PIXBUF/loaders.cache.tmp
 128     mv $GDK_PIXBUF/loaders.cache.tmp $GDK_PIXBUF/loaders.cache
 129   '';
 130
 131   postFixup = lib.optionalString withIntrospection ''
 132     # Cannot be in postInstall, otherwise _multioutDocs hook in preFixup will move right back.
 133     moveToOutput "share/doc" "$devdoc"
 134   '';
 135
 136   passthru = {
 137     updateScript =
 138       let
 139         updateSource = gnome.updateScript {
 140           packageName = "librsvg";
 141         };
 142
 143         updateLockfile = {
 144           command = [
 145             "sh"
 146             "-c"
 147             ''
 148               PATH=${lib.makeBinPath [
 149                 common-updater-scripts
 150                 jq
 151                 nix
 152               ]}
 153               # update-source-version does not allow updating to the same version so we need to clear it temporarily.
 154               # Get the current version so that we can restore it later.
 155               latestVersion=$(nix-instantiate --eval -A librsvg.version | jq --raw-output)
 156               # Clear the version. Provide hash so that we do not need to do pointless TOFU.
 157               # Needs to be a fake SRI hash that is non-zero, since u-s-v uses zero as a placeholder.
 158               # Also cannot be here verbatim or u-s-v would be confused what to replace.
 159               update-source-version librsvg 0 "sha256-${lib.fixedWidthString 44 "B" "="}" --source-key=cargoDeps > /dev/null
 160               update-source-version librsvg "$latestVersion" --source-key=cargoDeps > /dev/null
 161             ''
 162           ];
 163           # Experimental feature: do not copy!
 164           supportedFeatures = [ "silent" ];
 165         };
 166       in
 167       _experimental-update-script-combinators.sequence [
 168         updateSource
 169         updateLockfile
 170       ];
 171   };
 172
 173   meta = with lib; {
 174     description = "A small library to render SVG images to Cairo surfaces";
 175     homepage = "https://wiki.gnome.org/Projects/LibRsvg";
 176     license = licenses.lgpl2Plus;
 177     maintainers = teams.gnome.members;
 178     mainProgram = "rsvg-convert";
 179     platforms = platforms.unix;
 180   };
 181 }