pkgs/development/libraries/portaudio/default.nix

   1 { lib
   2 , stdenv
   3 , fetchurl
   4 , alsa-lib
   5 , pkg-config
   6 , which
   7 , AudioUnit
   8 , AudioToolbox
   9 , CoreAudio
  10 , CoreServices
  11 , Carbon }:
  12
  13 stdenv.mkDerivation rec {
  14   pname = "portaudio";
  15   version = "190700_20210406";
  16
  17   src = fetchurl {
  18     url = "http://files.portaudio.com/archives/pa_stable_v${version}.tgz";
  19     sha256 = "1vrdrd42jsnffh6rq8ap2c6fr4g9fcld89z649fs06bwqx1bzvs7";
  20   };
  21
  22   strictDeps = true;
  23   nativeBuildInputs = [ pkg-config which ];
  24   buildInputs = lib.optional (!stdenv.isDarwin) alsa-lib;
  25
  26   configureFlags = [ "--disable-mac-universal" "--enable-cxx" ];
  27
  28   NIX_CFLAGS_COMPILE = lib.optionalString stdenv.cc.isClang "-Wno-error=nullability-inferred-on-nested-type -Wno-error=nullability-completeness-on-arrays -Wno-error=implicit-const-int-float-conversion";
  29
  30   propagatedBuildInputs = lib.optionals stdenv.isDarwin [ AudioUnit AudioToolbox CoreAudio CoreServices Carbon ];
  31
  32   # Disable parallel build as it fails as:
  33   #   make: *** No rule to make target '../../../lib/libportaudio.la',
  34   #     needed by 'libportaudiocpp.la'.  Stop.
  35   # Next release should address it with
  36   #     https://github.com/PortAudio/portaudio/commit/28d2781d9216115543aa3f0a0ffb7b4ee0fac551.patch
  37   enableParallelBuilding = false;
  38
  39   postPatch = ''
  40     # workaround for the configure script which expects an absolute path
  41     export AR=$(which $AR)
  42   '';
  43
  44   # not sure why, but all the headers seem to be installed by the make install
  45   installPhase = ''
  46     make install
  47   '' + lib.optionalString (!stdenv.isDarwin) ''
  48     # fixup .pc file to find alsa library
  49     sed -i "s|-lasound|-L${alsa-lib.out}/lib -lasound|" "$out/lib/pkgconfig/"*.pc
  50   '' + lib.optionalString stdenv.isDarwin ''
  51     cp include/pa_mac_core.h $out/include/pa_mac_core.h
  52   '';
  53
  54   meta = with lib; {
  55     description = "Portable cross-platform Audio API";
  56     homepage    = "http://www.portaudio.com/";
  57     # Not exactly a bsd license, but alike
  58     license     = licenses.mit;
  59     maintainers = with maintainers; [ lovek323 ];
  60     platforms   = platforms.unix;
  61   };
  62
  63   passthru = {
  64     api_version = 19;
  65   };
  66 }