pkgs/development/libraries/qmltermwidget/default.nix

   1 { lib, stdenv, fetchFromGitHub, qtbase, qtquick1, qmake, qtmultimedia, utmp, fetchpatch }:
   2
   3 stdenv.mkDerivation {
   4   version = "2018-11-24";
   5   pname = "qmltermwidget-unstable";
   6
   7   src = fetchFromGitHub {
   8     repo = "qmltermwidget";
   9     owner = "Swordfish90";
  10     rev = "48274c75660e28d44af7c195e79accdf1bd44963";
  11     sha256 = "028nb1xp84jmakif5mmzx52q3rsjwckw27jdpahyaqw7j7i5znq6";
  12   };
  13
  14   buildInputs = [ qtbase qtquick1 qtmultimedia ]
  15                 ++ lib.optional stdenv.isDarwin utmp;
  16   nativeBuildInputs = [ qmake ];
  17
  18   patches = [
  19     (fetchpatch {
  20       name = "fix-missing-includes.patch";
  21       url = "https://github.com/Swordfish90/qmltermwidget/pull/27/commits/485f8d6d841b607ba49e55a791f7f587e4e193bc.diff";
  22       sha256 = "186s8pv3642vr4lxsds919h0y2vrkl61r7wqq9mc4a5zk5vprinj";
  23     })
  24   ];
  25
  26   postPatch = ''
  27     substituteInPlace qmltermwidget.pro \
  28       --replace '$$[QT_INSTALL_QML]' "/$qtQmlPrefix/"
  29   '';
  30
  31   installFlags = [ "INSTALL_ROOT=$(out)" ];
  32
  33   dontWrapQtApps = true;
  34
  35   meta = {
  36     description = "A QML port of qtermwidget";
  37     homepage = "https://github.com/Swordfish90/qmltermwidget";
  38     license = lib.licenses.gpl2;
  39     platforms = with lib.platforms; linux ++ darwin;
  40     maintainers = with lib.maintainers; [ skeidel ];
  41   };
  42 }