pkgs/development/ocaml-modules/afl-persistent/default.nix

   1 { lib, stdenv, fetchFromGitHub, ocaml, findlib, opaline }:
   2
   3 stdenv.mkDerivation rec {
   4   pname = "afl-persistent";
   5   version = "1.3";
   6   name = "ocaml${ocaml.version}-${pname}-${version}";
   7
   8   src = fetchFromGitHub {
   9     owner  = "stedolan";
  10     repo   = "ocaml-${pname}";
  11     rev    = "v${version}";
  12     sha256 = "06yyds2vcwlfr2nd3gvyrazlijjcrd1abnvkfpkaadgwdw3qam1i";
  13   };
  14
  15   nativeBuildInputs = [ ocaml findlib ];
  16
  17   # don't run tests in buildPhase
  18   # don't overwrite test binary
  19   postPatch = ''
  20     sed -i 's/ && \.\/test$//' build.sh
  21     sed -i '/^ocamlopt.*test.ml -o test$/ s/$/2/' build.sh
  22     patchShebangs build.sh
  23   '';
  24
  25   buildPhase = "./build.sh";
  26   installPhase = ''
  27     ${opaline}/bin/opaline -prefix $out -libdir $out/lib/ocaml/${ocaml.version}/site-lib/ ${pname}.install
  28   '';
  29
  30   doCheck = true;
  31   checkPhase = "./_build/test && ./_build/test2";
  32
  33   meta = with lib; {
  34     homepage = "https://github.com/stedolan/ocaml-afl-persistent";
  35     description = "persistent-mode afl-fuzz for ocaml";
  36     license = licenses.mit;
  37     maintainers = [ maintainers.sternenseemann ];
  38   };
  39 }